是否可以在批处理文件中使用管道标准输入流？
我希望能够将一个命令的输出重定向到我的批处理文件process.bat 列表中，所以：
C:\>someOtherProgram.exe | process.bat
我的第一次尝试是这样的：
echo OFF
setlocal
:again
set /p inputLine=""
echo.%inputLine%
if not (%inputLine%)==() goto again
endlocal
:End
当我使用type testFile.txt | process.bat 对其进行测试时，它会重复打印出第一行。
还有其他方法吗？
【问题讨论】：
标签： windows batch-file stdout stdin
set /p 不适用于管道，它从输入中获取一行（随机）。
但是您可以在 for 循环中使用 more。
@echo off
setlocal
for /F "tokens=*" %%a in ('more') do (
echo #%%a
)
但这会失败，因为行以分号开头（因为 eol 的 FOR-LOOP 标准是 ;）。
而且它不能读取空行。
但是使用 findstr 你也可以解决这个问题，它在每一行前面加上行号，所以你永远不会得到空行。
然后前缀被删除到第一个冒号。
@echo off
setlocal DisableDelayedExpansion
for /F "tokens=*" %%a in ('findstr /n $') do (
set "line=%%a"
setlocal EnableDelayedExpansion
set "line=!line:*:=!"
echo(!line!
endlocal
)
或者，在某些不包含findstr 的环境（如WinRE）上，使用find.exe 的替代方案可能就足够了。 find 将接受空搜索字符串""，并允许搜索反转。这将允许这样的事情：
@echo off
setlocal DisableDelayedExpansion
for /F "tokens=*" %%a in ('find /v ""') do (
...
【讨论】：
set "line=!line:*:=!" 语法。更多的批处理脚本疯狂。我已经稍微调整了它以使用 MSYS 工具； sed "s/^\(.*\)$/\"\1\"/"' 而不是 findstr /n $。然后可以用echo.%%~a 替换正文，它可以处理无dos 行结尾（我在很多文件中都有）。
FINDSTR /N "^"。该搜索将正确返回所有行，包括 unix 格式的行以及可能不以换行符结尾的任何最后一行。
for /F "tokens=* eol=" 来处理以分号开头的行。
设置“line=!line:*:=!”的语法是：
设置需要一个参数，即a=b。
如果 a 包含空格或其他内容，则必须在此参数周围使用引号。这里我没有看到任何
!line:*:=!
对于这种语法，你可以输入'set /?'来查看使用变量的官方说明。!var!类似于%var%，获取值。但!var! 表示延迟扩张。
行变量名
第一个：变量修改标记。
**:= **:=(empty)，将变量值中匹配“*:”的字符串（实际上从字符串开始到第一个:出现）替换为（空），即删除从开始到第一个冒号的子字符串.
【讨论】：
FOR /F "tokens=1* delims=]" %%A IN ('FIND /N /V ""') DO (
> CON ECHO.%%B
>> %File% ECHO.%%B
)
【讨论】：
] 开头的行上失败了。
或者，在某些不包含findstr 的环境（如WinRE）上，使用find.exe 的替代方案可能就足够了。 find 将接受空搜索字符串""，并允许搜索反转。这将允许这样的事情：
@echo off
setlocal DisableDelayedExpansion
for /F "tokens=*" %%a in ('find /v ""') do (
set "line=%%a"
echo(!line!
)
【讨论】：
!line! 当然不适用于DisableDelayedExpansion。此外，这不会打印空行。