批量带有额外后缀的文件

Question

我正在尝试列出所有在扩展名后有额外后缀的文件 例如：.txt.1 或 .txt.2 等。

我正在使用 txt.，但它给出了所有文件名，而不仅仅是带有额外后缀的文件

for %%A in (*txt.*) do (call :renum "%%A")

在此之后，我正在编写程序以相应地重命名文件。 有人可以检查并帮助。

Answer 1

一种解决方案是在循环内按扩展过滤：

FOR %%A IN (*txt.*) DO (
    IF NOT "%%~xA"==".txt" CALL :renum "%%A"
)

这通过使用“FOR 变量引用的增强替换”来工作，在本例中为%%~xA。您可以通过执行FOR /? 来获得所有可用替换的概览。

更新：

• 此解决方案不区分大小写，因为既没有明确要求也没有禁止。如果需要不区分大小写，请使用 IF /I 而不是普通的 IF。
• 正如dbenham 所说，有一些极端情况：
  • name.txt.txt 不会被处理。如果没问题没有明确说明，但很有可能。
  • name_txt.ext 将处理，这是由于给定的通配符 *txt.* 而可以通过使用 *.txt.* 来避免。我最初不更改它的理由是只有 OP 知道他的实际文件集，我认为他有选择它的理由（这种情况在这类问题中很常见）。

Answer 2

您可以像这样使用两个嵌套的for 循环：

rem // Corrected file pattern (added a `.`):
for %%A in ("*.txt.*") do (
    rem // Check (last) file extension:
    if /I not "%%~xA"==".txt" (
        rem // Remove (last) file extension:
        for %%B in ("%%~nA") do (
            rem // Check next-to-last file ext.:
            if /I "%%~xB"==".txt" (
                call :renum "%%~A"
            )
        )
    )
)

根据for（在命令提示符窗口中键入for /?）的帮助，for 变量的~x 修饰符检索文件扩展名（这是最后一个点. 以及之后的所有内容）。 ~n 修饰符检索除文件扩展名之外的所有内容，因此检索文件（基本）名称。上面的代码使用两个嵌套的for 循环来获取最后一个和倒数第二个文件扩展名，并根据.txt 检查它们（以不区分大小写的方式）。

请注意，call 命令行不会对以 .txt.txt 结尾的文件执行。

Answer 3

我会将 FINDSTR 与 DIR /B 和 FOR /F 一起使用

以下将处理带有任意数量的额外扩展名的名称，例如 name.txt.ext 和 name.txt.ext.ext 等。这包括像 name.txt.txt 这样的名称

for /f "delims= eol=:" %%F in (
  'dir /b /a-d *.txt.*^|findstr /i "\.txt\."'
) do call :renum "%%F"

此变体将仅处理具有单个额外扩展名的名称，例如 name.txt.ext（包括 name.txt.txt）

for /f "delims= eol=:" %%F in (
  'dir /b /a-d *.txt.*^|findstr /i "\.txt\.[^.]*$"'
) do call :renum "%%F"

您也可以查看我的JREN.BAT regular expression file renaming utility。它可能可以一步过滤和重命名您的所有文件，而无需任何自定义批处理脚本。

例如，以下只会重命名看起来像“name.txt.ext”的文件，并将它们转换为“name_ext.txt”

jren "(\.txt)\.([^.]+)$" "_$2$1" /i