我有许多日志文件，我想从中提取特定文本并使用 FINDSTR 命令将其复制到新文件中，
例如：我有一个名为 1.log 的日志文件，我需要提取日志文件中所有以 N66666 行开头的数字，如下所示：
22220473400664->473400664
01210260222->01210260222->N8888801210260222
01278448231->01278448231->N6666601278448231
01286799109->01286799109->N8888801286799109
我试过了：
findstr /s /i "\<N66666.*" *.* > results.txt
但结果是以N6666 开头的整行复制到results.txt，我只需要将数字复制到results.txt。
【问题讨论】：
标签： windows batch-file cmd findstr
@ECHO OFF
SETLOCAL
SET "targetstring=N66666"
FOR /f "tokens=3delims=>" %%a IN ('findstr /s /i "%targetstring%.*" *.*') DO ECHO(%%a
GOTO :EOF
这可能有用 - 您提供的信息非常少。
它依赖于您所需的数据，即所需行中第二个> 字符之后的字符串；我没有将结果重定向到文件，因为这是一个微不足道的修改。
根据更多信息：
@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SET "targetstring=N66666"
SET /a ltargetstring=0
SET "output=%targetstring%"
:dtslp
SET /a ltargetstring+=1
SET "output=%output:~1%"
IF DEFINED output GOTO dtslp
FOR /f "delims=" %%a IN ('findstr /s /i "%targetstring%.*" *.*') DO (
SET "line=%%a"
SET "line=!line:>= !"
SET "line=!line:<= !"
SET "line=!line:"=!"
CALL :process !line!
)
GOTO :EOF
:process
SET "output=%1"
IF NOT DEFINED output GOTO :EOF
CALL SET "output=%%output:~0,%ltargetstring%%%"
IF /i "%output%" neq "%targetstring%" GOTO miss
SET "output=%1"
CALL SET "output=%%output:~%ltargetstring%%%"
ECHO(%output%
:miss
SHIFT
GOTO process
您提供的信息应该已经编辑到您的问题中，而不是作为 cmets 发布。
您尚未回答原始解决方案依赖于“您所需的数据是所需行中第二个 > 字符之后的字符串中的数据”这一点，您已声明所需的输出“数字”是在“N66666”和下一个空格之间（或者，给定提供的数据，行尾；没有示例表明行上超出所需字符串的额外数据）
所以还有很多猜测。
此过程从文件中读取包含目标字符串的每一行，然后用空格替换 ech ">" 和 ""
然后使用标准分隔符处理结果字符串，方法是使用子字符串方法将找到的每个子字符串与目标字符串匹配，该方法将初始化时计算的目标字符串的长度应用于ltargetstring。
如果找到的字符串的第一部分与目标匹配，则提取字符串的其余部分并echoed 并重复该过程，直到:process 没有更多参数为止。
【讨论】：