Erlang：以有效的方式从输入流中读取

Question

我正在编写一个从 input 流中读取的程序，即

erl -run p main -noshell -s erlang halt < input

问题是使用这个读取函数读取它需要很多时间（输入流很大）：

read_input(L) ->
    case io:get_line("") of
        eof ->
            lists:reverse(L);
        E0 ->
            read_input([E0|L])
    end.

我一直在寻找更有效的替代方案，但一无所获。我尝试使用

读取文件

{ok, Binary} = file:read_file("input")

这要高效得多。问题是我必须在名称未知的平台上运行这个程序，所以我需要一些替代方法。另外，我无法选择运行时使用的标志，例如flag -noinput 不能添加到命令行。

我们欢迎您提供任何帮助。

Answer 1

虽然Steve's solution 是我最快知道的解决方案，但可以使用性能相当好的file 模块解决方案：

-module(p).

-export([start/0]).

-define(BLK_SIZE, 16384).

start() ->
    do(),
    halt().

do() ->
    Bin = read(),
    io:format("~p~n", [byte_size(Bin)]).

read() ->
    ok = io:setopts(standard_io, [binary]),
    read(<<>>).

read(Acc) ->
    case file:read(standard_io, ?BLK_SIZE) of
        {ok, Data} ->
            read(<<Acc/bytes, Data/bytes>>);
        eof ->
            Acc
    end.

它适用于以下调用：

erl -noshell -s p < input

注意，这两种方法都可以用于面向行的输入，使用{line, Max_Line_Size} 端口选项或file:read_line/1 用于file 模块解决方案。从第 17 版开始（如果我没记错的话），我发现 file:read_line/1 中存在固定的性能错误，所以现在很好。无论如何，您不应该期望 Perl 的性能和舒适性。

Answer 2

您可以使用open_port/2 打开标准输入并从中读取二进制文件。例如：

-module(p).
-export([start/0]).

start() ->
    process_flag(trap_exit, true),
    P = open_port({fd,0,1}, [in, binary]),
    Bin = read(P,<<>>),
    io:format("received ~p\n", [Bin]),
    halt(0).

read(P, Bin) ->
    receive
        {P, {data, Data}} ->
            read(P, <<Bin/binary, Data/binary>>);
        {'EXIT',P,_} ->
            Bin
    end.

代码必须捕获出口，以便它知道在端口关闭时退出其读取循环。此示例将所有内容读入从 read/2 函数返回的单个二进制文件中，然后将其打印出来并退出，但显然您可以在实际应用程序中对二进制文件执行进一步的操作。

你可以这样运行：

erl -noinput -s p < input