制作下一个节点不是前一个节点的路径？

Question

我在一个图中有大约 150 万个节点，它们的结构是这样的（图片）

我运行一个 Cypher 查询，对遍历的每个关系执行计算：

WITH 1 AS startVal
MATCH x = (c:Currency)-[r:Arb*2]->(m)
WITH x, REDUCE(s = startVal, e IN r | s * e.rate) AS endVal, startVal
RETURN EXTRACT(n IN NODES(x) | n) as Exchanges,
    extract ( e IN relationships(x) | startVal * e.rate) AS Rel,
    endVal, endVal - startVal AS Profit
ORDER BY Profit DESC LIMIT 5

问题是它返回路径("One")->("hop")->("One")，这对我来说没用。

如何让它不选择之前遍历的节点作为下一个节点（即"One"->"hop"->"any_other_node_but_not_"one"）？

我已阅读 NODE_RECENT 应该解决我的问题。但是，没有关于如何在 RestAPI 或 APOC 过程中指定最近节点长度的示例。

是否有针对我的案例的 Cypher 查询？

谢谢。

附：我对 Neo4j 和编码非常陌生（不到 2 个月）。因此，如果有明显的简单解决方案，我深表歉意。

Answer 1

我不知道我是否完全理解了你的问题，但我相信你的问题可以在MATCH 上放置一个WHERE 子句来解决，以防止匹配不想要的关系，如下所示：

WITH 1 AS startVal
MATCH x = (c:Currency)-[r:Arb*2]->(m)
WHERE NOT (m)-[:Arb]->(c)
WITH x, REDUCE(s = startVal, e IN r | s * e.rate) AS endVal, startVal
RETURN EXTRACT(n IN NODES(x) | n) as Exchanges,
    extract ( e IN relationships(x) | startVal * e.rate) AS Rel,
    endVal, endVal - startVal AS Profit
ORDER BY Profit DESC LIMIT 5

Answer 2

尝试在 MATCH 子句之后插入此子句，以过滤掉 c 和 m 相同的情况：

WHERE c <> m

[编辑]

即：

WITH 1 AS startVal
MATCH x = (c:Currency)-[r:Arb*2]->(m)
WHERE c <> m
WITH x, REDUCE(s = startVal, e IN r | s * e.rate) AS endVal, startVal
RETURN EXTRACT(n IN NODES(x) | n) as Exchanges,
    extract ( e IN relationships(x) | startVal * e.rate) AS Rel,
    endVal, endVal - startVal AS Profit
ORDER BY Profit DESC LIMIT 5;

使用此查询创建测试数据后：

CREATE
  (c:Currency {name: 'One'})-[:Arb {rate:1}]->(h:Account {name: 'hop'})-[:Arb {rate:2}]->(t:Currency {name: 'Two'}),
  (t)-[:Arb {rate:3}]->(h)-[:Arb {rate:4}]->(c)

上述查询产生以下结果：

+-----------------------------------------------------------------------------------------+
| Exchanges                                                     | Rel   | endVal | Profit |
+-----------------------------------------------------------------------------------------+
| [Node[8]{name:"Two"},Node[7]{name:"hop"},Node[6]{name:"One"}] | [3,4] | 12     | 11     |
| [Node[6]{name:"One"},Node[7]{name:"hop"},Node[8]{name:"Two"}] | [1,2] | 2      | 1      |
+-----------------------------------------------------------------------------------------+