如何在 VB.NET 中将对象转换为整数？

Question

我应该如何在 VB.NET 中将 Object 转换为 Integer？

当我这样做时：

Dim intMyInteger as Integer = TryCast(MyObject, Integer)

上面写着：

TryCast 操作数必须是引用类型，但 Integer 是值类型。

Answer 1

TryCast 相当于 C# 的 as 运算符。它是一个“安全转换”运算符，如果转换失败，它不会抛出异常。相反，它返回Nothing（C# 中的null）。问题是，您不能将Nothing (null)（引用类型）分配给Integer（值类型）。没有 Integer null/Nothing 这样的东西。

相反，您可以使用TypeOf 和Is：

If TypeOf MyObject Is Integer Then
    intMyInteger = DirectCast(MyObject, Integer)
Else
    intMyInteger = 0
End If

这将测试MyObject 的运行时类型 是否为Integer。有关详细信息，请参阅MSDN documentation on the TypeOf operator。

你也可以这样写：

Dim myInt As Integer = If(TypeOf myObj Is Integer, DirectCast(myObj,Integer), 0)

此外，如果一个具有默认值（如 0）的整数不适合，您可以考虑使用Nullable(Of Integer) 类型。

Answer 2

你可以用这个：

Dim intMyInteger as Integer

Integer.TryParse(MyObject, intMyInteger)

Answer 3

使用 Directcast 并捕获 InvalidCastException

Answer 4

TryCast 的等效项是 CType。如果可能，两者都会进行类型转换。相比之下，DirectCast 只会在它是该类型的情况下转换该类型。

为了说明，您可以使用 CType 将 String、Short 或 Double 转换为 Integer。如果你这样做，DirectCast 通常会给你一个语法/编译错误；但是如果您尝试使用类型 Object 来绕过错误（这称为“装箱”和“拆箱”），它将在运行时抛出异常。

    Dim OnePointTwo As Object = "1.2"
    Try
        Dim temp = CType(OnePointTwo, Integer)
        Console.WriteLine("CType converted to: " & temp.ToString & " (type: " & temp.GetType.ToString & ")")
    Catch ex As Exception
        Console.WriteLine("CType threw exception")
    End Try
    Try
        Dim temp = DirectCast(OnePointTwo, Integer)
        Console.WriteLine("DirectCast converted to: " & temp.ToString & " (type: " & temp.GetType.ToString & ")")
    Catch ex As Exception
        Console.WriteLine("DirectCast threw exception")
    End Try

这将输出：

    CType converted to: 1 (type: System.Int32)
    DirectCast threw exception

所以为了最严格地遵循 TryCast 语义，我建议使用这样的函数：

Shared Function TryCastInteger(value As Object) As Integer?
    Try
        If IsNumeric(value) Then
            Return CType(value, Integer)
        Else
            Return Nothing
        End If
    Catch ex As Exception
        Return Nothing
    End Try
End Function

并说明其效果：

Shared Sub TestTryCastInteger()
    Dim temp As Integer?

    Dim OnePointTwo As Object = "1.2"
    temp = TryCastInteger(OnePointTwo)
    If temp Is Nothing Then
        Console.WriteLine("Could not convert to Integer")
    Else
        Console.WriteLine("TryCastInteger converted to: " & temp.ToString & " (type: " & temp.GetType.ToString & ")")
    End If

    Dim NotANumber As Object = "bob's your uncle"
    temp = TryCastInteger(NotANumber)
    If temp Is Nothing Then
        Console.WriteLine("Could not convert to Integer")
    Else
        Console.WriteLine("TryCastInteger converted to: " & temp.ToString & " (type: " & temp.GetType.ToString & ")")
    End If
End Sub

运行 TestTryCastInteger() 将输出：

    TryCastInteger converted to: 1 (type: System.Int32)
    Could not convert to Integer

还有 is 诸如 null/Nothing Integer 或任何其他静态类型，称为“可空”类型，请参阅 Variable declaration question mark 了解更多信息信息。但这也不能真正使它成为“参考”类型。