使用 RTTI 读取/写入泛型类型的属性时出错

Question

我正在使用泛型类来允许我访问泛型类型的命名属性并读/写它的值。尝试从 RTTIProperty 记录访问 GetValue 调用的结果以及使用 SetValue 设置值时，我收到 EAccessViolation 错误。运行跟踪时，访问 TValue 时似乎都抛出了两个错误。我在下面包含了一个示例控制台应用程序，它突出了这个问题。

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils,
  System.RTTI;

Type
  TTestClass = class
  private
    FItem: string;
  public
    Property Item: string read FItem write FItem;
  end;

  TAccessData<T> = class
    Function GetTValue(AItem : T; AField : string) : TValue;
    Procedure SetTValue(AItem : T; Afield : string; AValue : TValue);
  end;

{ TAccessData<T> }

function TAccessData<T>.GetTValue(AItem: T; AField: string): TValue;
var
  LContext : TRTTIContext;
  LType : TRttiType;
  LProperty : TRttiProperty;

begin
  result := nil;
  LType := LContext.GetType(Typeinfo(T));
  LProperty := LType.GetProperty(Afield);
  if LProperty <> nil then
    Result := LProperty.GetValue(@AItem);
end;

var
  LTestObj : TTestClass;
  LAccessOBj : TAccessData<TTestClass>;
  AValue : TValue;

procedure TAccessData<T>.SetTValue(AItem: T; Afield: string; AValue: TValue);
var
  LContext : TRTTIContext;
  LType : TRttiType;
  LProperty : TRttiProperty;

begin
  LType := LContext.GetType(Typeinfo(T));
  LProperty := LType.GetProperty(Afield);
  if LProperty <> nil then
    LProperty.SetValue(@AItem, AValue);
end;

begin
  try
    LTestObj := TTestClass.Create;
    LTestObj.Item := 'Hello';
    Writeln(LTestObj.Item);
    LAccessOBj := TAccessData<TTestClass>.Create;
    AValue := LAccessObj.GetTValue(LTestObj, 'Item');
    Writeln(AValue.TypeInfo^.Name);
    if AValue.TypeInfo.Kind <> tkString then
      Writeln('Not string');
    Writeln(AValue.ToString); // <--- This results in a EAccessViolation
    LAccessOBj.SetTValue(LTestObj,'Item','World'); // <--- This results in a EAccessViolation
    Writeln(LTestObj.Item);
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

我怀疑我在访问泛型类型的属性的方式上遗漏了一些东西，但是对于我为什么会出现这种行为已经碰壁了。我没有对泛型参数做出限制，因为我也需要它来处理记录类型。

使用东京更新 1

Answer 1

您在GetTValue 和SetTValue 中的代码存在缺陷，因为它将@AItem 传递给TRttiProperty.SetValue 和GetValue。它需要是PPointer(@AItem)^ 或将T 限制为class，这样您就可以直接使用Pointer(AItem) 进行硬铸。

由于错误传递的AInstance TValue 包含一些垃圾内存，如果您引入字符串变量并在尝试将其传递给Writeln 之前将ToString 调用的结果分配给它，您可以看到这些内存.然后Writeln 中的代码正在生成 AV。