如何在 vb.net 中创建可取消事件

Question

在 VB.NET（不是 c#）中...

我想创建一个可以被侦听器取消的事件。就像您可以取消 winforms 表单的关闭事件，在这种情况下表单不会关闭。

我已经从 EventArgs 实现了一个派生类，它有一个可设置的 Cancel 属性，如下所示：

Public Class AnnounceNavigateEventArgs
    Inherits EventArgs

    Private _cancel As Boolean = False

    ''' <summary>
    ''' Initializes a new instance of the AnnounceNavigateEventArgs class.
    ''' </summary>
    Public Sub New(ByRef cancel As Boolean)
        _cancel = cancel
    End Sub
    Public Property Cancel() As Boolean
        Get
            Return _cancel
        End Get
        Set(ByVal value As Boolean)
            _cancel = value
        End Set
    End Property

End Class

请注意，我将取消参数 byRef 传递给构造函数。

我设置的侦听器将属性设置为 Cancel=True。我认为 ByRef 意味着 _cancel 和 cancel 都将指向堆栈上的相同位置，因此设置 _cancel=true 会使 cancel = true。但这不是我得到的行为。 _cancel 在 setter 中变为 true，但我猜构造函数的参数仍然为 false。

在 vb.net 中执行此操作的正确方法是什么？

赛斯

Answer 1

您可以在 .NET 框架中重复使用 System.ComponentModel.CancelEventArgs 类。

Public Event Announcing As EventHandler(Of AnnounceNavigateEventArgs)

Protected Sub OnAnnounce()
    Dim e As New AnnounceNavigateEventArgs

    RaiseEvent Announcing(Me, e)

    If Not e.Cancel Then
        ' announce
    End If
End Sub

Public Class AnnounceNavigateEventArgs
    Inherits System.ComponentModel.CancelEventArgs
End Class