Perl 从调用模块导入变量

Question

我有一个 Perl 模块 (Module.pm)，它初始化了许多变量，我想将其中一些变量 ($VAR2, $VAR3) 导入到可能在执行期间加载的其他子模块中。

我目前设置Module.pm的方式如下：

package Module;

use warnings;
use strict;

use vars qw($SUBMODULES $VAR1 $VAR2 $VAR3);

require Exporter;
our @ISA = qw(Exporter);
our @EXPORT = qw($VAR2 $VAR3);

sub new {
    my ($package) = @_;
    my $self = {};
    bless ($self, $package);
    return $self;
}

sub SubModules1 {
    my $self = shift;
    if($SUBMODULES->{'1'}) { return $SUBMODULES->{'1'}; }

    # Load & cache submodule
    require Module::SubModule1;
    $SUBMODULES->{'1'} = Module::SubModule1->new(@_);    
    return $SUBMODULES->{'1'};
}

sub SubModules2 {
    my $self = shift;
    if($SUBMODULES->{'2'}) { return $SUBMODULES->{'2'}; }

    # Load & cache submodule
    require Module::SubModule2;
    $SUBMODULES->{'2'} = Module::SubModule2->new(@_);    
    return $SUBMODULES->{'2'};
}

每个子模块的结构如下：

package Module::SubModule1;

use warnings;
use strict;
use Carp;

use vars qw();

sub new {
    my ($package) = @_;
    my $self = {};
    bless ($self, $package);
    return $self;
}

我希望能够将 $VAR2 和 $VAR3 变量导入每个子模块，而不必将它们引用为 $Module::VAR2 和 $Module::VAR3。我注意到调用脚本能够以所需的方式访问我在 Module.pm 中导出的两个变量，但 SubModule1.pm 和 SubModule2.pm 仍然必须引用来自 Module.pm 的变量。

我尝试如下更新每个子模块，但不幸的是，我希望它没有工作：

package Module::SubModule1;

use warnings;
use strict;
use Carp;

use vars qw($VAR2 $VAR3);

sub new {
    my ($package) = @_;
    my $self = {};
    bless ($self, $package);
    $VAR2 = $Module::VAR2;
    $VAR3 = $Module::VAR3;
    return $self;
}

请告诉我如何成功地将 $VAR2 和 $VAR3 从 Module.pm 导出到每个子模块中。提前感谢您的帮助！

Answer 1

在你的子模块中，你忘了说

use Module;

？从另一个包（比如Module::Submodule9）调用use Module 将尝试运行Module::import 方法。由于您没有该方法，它将调用Exporter::import 方法，这就是将Module 的变量导出到Module::Submodule9 命名空间的神奇之处。

---

在你的程序中只有一个Module 命名空间和只有一个（全局）变量$Module::VAR2 的实例。导出会在其他命名空间中创建此变量的别名，因此可以以不同的方式访问同一个变量。在单独的脚本中尝试：

package Whatever;
use Module;
use strict;
use vars qw($VAR2);

$Module::VAR2 = 5;
print $Whatever::VAR2;    # should be 5.
$VAR2 = 14;               # same as $Whatever::VAR2 = 14
print $Module::VAR2;      # should be 14

Answer 2

有一个简单的方法：

在下午：

package M;

use strict;
use warnings;

#our is better than "use vars" for creating package variables
#it creates an alias to $M::foo named $foo in the current lexical scope 
our $foo = 5;

sub inM { print "$foo\n" }

1;

在 M/S.pm

package M;

#creates an alias to $M::foo that will last for the entire scope,
#in this case the entire file
our $foo;

package M::S;

use strict;
use warnings;

sub inMS { print "$foo\n" }

1;

在脚本中：

#!/usr/bin/perl

use strict;
use warnings;

use M;
use M::S;

M::inM();
M::S::inMS();

但我建议不要这样做。全局变量不是一个好习惯，在模块之间共享全局变量更糟糕。