简洁地创建一个 IDictionary<_,obj>

Question

有没有更短的方法来创建IDictionary<_,obj>，可能不需要对每个值进行装箱？这就是我所拥有的。

let values =
  [ "a", box 1
    "b", box "foo"
    "c", box true ]
  |> dict

Dictionary<_,obj>.Add 可以在没有装箱的情况下调用，但我想不出比我拥有的更短的使用方法。

除了定义一个装箱操作符之外，我还希望有别的东西。

编辑

根据 Brian 的建议，这是一种方法，但它有其自身的问题。

let values =
  Seq.zip ["a"; "b"; "c"] ([1; "foo"; true] : obj list) |> dict

Answer 1

这是一个解决方案，遵循 kvb 的建议（可能是迄今为止最简洁、最清晰的）：

let inline (=>) a b = a, box b

let values =
  [ "a" => 1
    "b" => "foo"
    "c" => true ]
  |> dict

Answer 2

这是我能做的最巧妙的事情。它比你的拳击版本有更多的字符，但可能感觉不那么脏。请注意，^ 是右关联的（它是从 ocaml 继承的字符串 concat 运算符），它可以像:: 一样工作，并且它比, 具有更高的优先级，这就是为什么需要在元组周围加上括号的原因.

let inline (^+) (x1:'a,x2:'b) (xl:('a*obj) list) = 
    (x1,box x2)::xl

let values =
  ("a", 1) ^+  ("b", "foo") ^+ ("c", true) ^+ []
  |> dict

Answer 3

我在 FsSql 中遇到了类似的问题，我只是将装箱隐藏在一个函数中：

let inline T (a,b) = a, box b
let values = dict [T("a",1); T("b","foo"); T("c",true)]

Answer 4

这是另一个“解决方案”，灵感来自 Brian 的建议，但它使用反射，因此需要时间和安全成本。

let unboxPair (pair:obj) =
    let ty = pair.GetType()
    let x = ty.GetProperty("Item1").GetValue(pair,null) :?> string
    let y = ty.GetProperty("Item2").GetValue(pair,null)
    x,y

let unboxPairs (pairs:obj list) =
  pairs |> List.map unboxPair  

let values =
  unboxPairs
    ["a", 1
     "b", "foo"
     "c", true]
  |> dict

Answer 5

斯蒂芬想法的变体：

open System
open System.Collections.Generic

type Dictionary<'a,'b> with
  member this.Add([<ParamArray>] args:obj[]) =
    match args.Length with
    | n when n % 2 = 0 ->
      for i in 1..2..(n-1) do
        this.Add(unbox args.[i-1], unbox args.[i])
    | _ -> invalidArg "args" "even number of elements required"

let d = Dictionary<string,obj>()
d.Add(
  "a", 1,
  "b", "foo",
  "c", true
)

Answer 6

另一种解决方案，只需在Dictionary<'a,'b>上定义一堆重载的扩展成员：

open System.Collections.Generic
type Dictionary<'a,'b> with
    member this.Add(x1,y1,x2,y2) =
        this.Add(x1,y1)
        this.Add(x2,y2)
    member this.Add(x1,y1,x2,y2,x3,y3) =
        this.Add(x1,y1,x2,y2)
        this.Add(x3,y3)
    member this.Add(x1,y1,x2,y2,x3,y3,x4,y4) =
        this.Add(x1,y1,x2,y2,x3,y3)
        this.Add(x4,y4)
    member this.Add(x1,y1,x2,y2,x3,y3,x4,y4,x5,y5) =
        this.Add(x1,y1,x2,y2,x3,y3,x4,y4)
        this.Add(x5,y5)
    member this.Add(x1,y1,x2,y2,x3,y3,x4,y4,x5,y5,x6,y6) =
        this.Add(x1,y1,x2,y2,x3,y3,x4,y4,x5,y5)
        this.Add(x6,y6)
    //etc.

let values = 
    let d = Dictionary<_,obj>()
    d.Add("a", 1, 
          "b", "foo", 
          "c", true)
    d

当然，values 这里不是像你的问题一样是不可变的，但我相信你可以在这个目标中采用相同的策略。

Answer 7

let v : (string*obj) list = [...]
let values = dict v

是一种方式，列表文字左侧的类型签名将自动向上转换每个元素。