迭代 Data.Set 直到成功

Question

假设我有一个函数表示一些可能失败的计算

f :: a -> Maybe b

如果我有一个列表l，我可以使用findList f l 在列表中找到f 成功的第一个（从左到右扫描时）项目，其中findList 是以下函数

findList :: (a -> Maybe b) -> [a] -> Maybe b
findList f [] = Nothing
findList f (x : xs) = case f x of
  Nothing -> findList f xs
  Just y -> Just y

（或使用，例如，extra 包中的 firstJust）。

问题。

如果我想用来自containers 的Set 做同样的事情该怎么办？

也就是说，我想要一个带签名的函数

findSet :: (a -> Maybe b) -> Set a -> Maybe b

相当于

findSet f s = findList f (Set.toList s)

上面的行作为一个实现。但是，我不想创建中间列表Set.toList s（即使使用惰性求值，仍然存在一些不必要的开销，对吧？）。

一旦找到成功的项目，我也不想遍历整个集合，如以下实现所示：

findSet f s = foldl g Nothing s
  where
    g Nothing x = f x
    g (Just y) _ = Just y

那么有没有一种好方法可以遍历一个“从左到右”的集合，对每个成员应用一个可能失败的计算，然后在第一个成功的结果处停止？

Answer 1

我想分享一个 IRC 上有人曾经向我展示过的小技巧：成功时提前退出只是错误时提前退出的另一种解释。考虑到这一点，考虑使用Either b () 而不是Maybe b；那么

findOne :: (a -> Either b ()) -> Set a -> Either b ()
findOne = traverse_

几乎不值得命名。如果你必须有Maybe，你可以简单地用明显的同构包装它。

findOneMaybe :: (a -> Maybe b) -> Set a -> Maybe b
findOneMaybe f = to . traverse_ (from . f) where
    from = maybe (Right ()) Left
    to = either Just (const Nothing)

Answer 2

您可以使用Set 是Foldable 的实例这一事实。因此，您可以使用以下方法实现Fold 函数：

import Control.Applicative((<|>))

findSet :: (a -> Maybe b) -> Set a -> Maybe b
findSet f = foldr ((<|>) . f) Nothing

这实际上可以与Foldable 的所有实例一起工作：

import Control.Applicative((<|>))

findSet :: (Alternative g, Foldable f) => (a -> g b) -> f a -> g b
findSet f = foldr ((<|>) . f) Nothing

或者作为@DanielWagner says，我们可以使用First，因为First会选择第一个Just，因此可以使用：

import Control.Applicative((<|>))

findSet :: Foldable f => (a -> Maybe b) -> f a -> Maybe b
findSet f = getFirst . foldMap (First . f)

toList的实现也是按照Foldable来实现的：

toList :: Foldable f => f a -> [a]
toList = foldr (:) []

所以我们在这里所做的不是先将它包装在一个 cons 中然后再打开它，而是立即应用 f 并使用 (<|>) :: Alternate f => f a -> f a -> f a 的实现。