F# 中的 NullReferenceException

Question

当我单步执行以下代码时，第二行的report 为空。 但是，第三行会生成 NullReferenceException。

member this.setTaggedResearchReportList (index : int) (taggedResearchReport : TaggedResearchReportUIVO option) =
    let report = Option.get(taggedResearchReport)
    if not(report.Equals(null)) then
        // do some stuff here

为什么会这样，我能做些什么来避免它？谢谢！

稍后添加：

这是调用this.setTaggedResearchReportList的行：

getMostRecentTaggedResearchReportForSecurityId (item.id) (new Action<_>(this.setTaggedResearchReportList 0))

这是getMostRecentTaggedResearchReportForSecurityId 方法：

let getMostRecentTaggedResearchReportForSecurityId (securityId : int) (callbackUI : Action<_>) =
    getSingleRPCResult<JSONSingleResult<TaggedResearchReportUIVO>, TaggedResearchReportUIVO>
        "TaggedResearchReportRPC"  
        "getMostRecentResearchReportForSecurityId" 
        (sprintf "%i" securityId)
        callbackUI
        (fun (x : option<JSONSingleResult<TaggedResearchReportUIVO>>) ->
            match x.IsSome with
                | true -> Some(Option.get(x).result)
                | false -> None 
        )

Answer 1

这本身不是一个答案，而是为了增加对空值处理的讨论，特别是在与 C# 代码互操作时：我喜欢避免使用 [<AllowNullLiteral>] 属性并定义一个如下所示的模块在 F# 代码中隔离 null 的使用。

[<AutoOpen>]
module Interop =

    let inline isNull value = System.Object.ReferenceEquals(value, null)
    let inline nil<'T> = Unchecked.defaultof<'T>
    let inline safeUnbox value = if isNull value then nil else unbox value
    let (|Null|_|) value = if isNull value then Some() else None

type Foo() = class end

type Test() =
    member this.AcceptFoo(foo:Foo) = //passed from C#
        if isNull foo then nullArg "foo"
        else ...

    member this.AcceptFoo2(foo:Foo) = //passed from C#
        match foo with
        | Null -> nullArg "foo"
        | _ -> ...

    member this.AcceptBoxedFoo(boxedFoo:obj) =
        let foo : Foo = safeUnbox boxedFoo
        ...

    member this.ReturnFoo() : Foo = //returning to C#
        if (test) then new Foo()
        else nil

一般而言，这些检查应尽可能靠近您的 API 接口，由于保留了编译器的空检查，您通常可以忘记 F# 中的 null。

Answer 2

您的 TaggedResearchReportUIVO 类型显然是在 F# 中定义的，并且不允许将 null 作为正确的值。因此，编译器将阻止您使用文字 null 作为该类型的值；但是，其他一些代码在编译器的背后并在其中粘贴了一个空值。要解决眼前的问题，您可以尝试与 Unchecked.defaultof<TaggedResearchReportUIVO> 而不是 null 进行比较。

但是，您可能值得评估一下您是否应该首先进行一些更重大的更改来避免此类问题。例如，如果将null 作为TaggedResearchReportUIVO 类型的正确值是有意义的，那么您可以将[<AllowNullLiteral>] 属性添加到该类型的定义中。或者，如果使用 null 作为正确的值确实没有意义，那么您需要调查生成有问题的值的代码。

顺便说一句，您的代码的其他部分可以进行大量清理。例如，考虑改变

fun (x : option<JSONSingleResult<TaggedResearchReportUIVO>>) -> 
    match x.IsSome with
    | true -> Some(Option.get(x).result)
    | false -> None

到

Option.map (fun (jsr : JSONSingleResult<_>) -> jsr.result)

Answer 3

由于taggedResearchReport 是option 类型，您希望在此处为您的逻辑使用模式匹配：

member this.setTaggedResearchReportList (index : int) (taggedResearchReport : TaggedResearchReportUIVO option) =
   match taggedResearchReport with
   | Some(report) -> //do some stuff when we have "something"
   | None -> //do some different stuff when we have "nothing"

更新

我对您添加的附加代码有点迷茫，但是您使用选项类型的方式肯定有一些时髦的东西。使用模式匹配代替IsSome 和Option.get。例如在你的 lambda 表达式中应该看起来更像这样：

(fun (x : option<JSONSingleResult<TaggedResearchReportUIVO>>) ->
            match x with
                | Some(value) -> Some(value.result)
                | None -> None 
        )

我不确定这是否能解决您的问题，但这是一个开始。

Answer 4

正如其他人指出的那样，问题在于反序列化器可能返回null，但由于您使用的是F#类型，因此您无法直接检查该值是否为null！

我认为最好的方法是尽早摆脱来自某些 .NET 库的null 值，这样您就可以保持其余代码干净。以下是我认为可以修复的方法：

let getMostRecentTaggedResearchReportForSecurityId 
        (securityId : int) (callbackUI : Action<_>) =
    getSingleRPCResult< JSONSingleResult<TaggedResearchReportUIVO>, 
                        TaggedResearchReportUIVO >
        "TaggedResearchReportRPC"  
        "getMostRecentResearchReportForSecurityId" 
        (sprintf "%i" securityId)
        callbackUI
        (fun (x : option<JSONSingleResult<TaggedResearchReportUIVO>>) ->
            // Note: Return 'Some' only when the result is 'Some' and the 'result'
            // value carried inside the discriminated union is not 'null'
            match x with
            | Some(res) when 
                  // Make sure that there are no dangerous values (I suppose 
                  // JSONSingleResult is imported from .NET and 
                  // TaggedResearchReportUIVO is your F# type.
                  res <> null && res.result <> Unchecked.defaultOf<_> -> 
                Some(res.result)
            | _ -> None )

然后您可以安全地使用模式匹配来处理该值，因为它永远不会是null：

member this.setTaggedResearchReportList 
        (index : int) (taggedResearchReport : TaggedResearchReportUIVO option) =
    match taggedResearchReport with 
    | Some(report) ->
        // do some stuff here
    | _ -> () // do nothing here

我可能不会使用AllowNullLiteral，因为您遇到此问题的唯一地方是从 JSON 库获取结果时。一旦在那里解决了问题，您就可以在 F# 代码中的其他任何地方安全地使用该值（无需检查 null）。

Answer 5

如果report为null，则不能调用report.Equals，所以代码没用。将其更改为report = null。此外，将taggedResearchReport 定义为option 并检查null 似乎是一个错误的用例。