如何通过自定义 Excel 功能区打开用户窗体

Question

我正在尝试通过自定义 Excel 功能区打开用户窗体。当我单击功能区中的按钮时，它开始初始化并在 workbooks.open 函数上将代码发送到 queryclose 子。显示用户表单代码如下：

Sub RemoveFixture_onAction(control As IRibbonControl)
    SelectedCompType = Fixture
    Set EditComp = New ufUpdateComp
        With EditComp
            .Top = Application.Top + 125
            .Left = Application.Left + 25
            .Show
        End With
End Sub

当代码开始 userform_Initialize 代码时，它最终移动到 query_close 子。代码如下：

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    'If wb Is Nothing Then UserForm_Initialize
    wb.Close False
End Sub

如上所示，在注释掉的部分中，当代码移至 queryclose 函数时，我尝试返回到初始化子程序。当它运行 workbooks.open 代码时，它移动到 queryclose 子，它说 wb 什么都不是。我尝试单独打开工作簿，然后将工作簿设置为 ActiveWorkbook。我也试过： wb什么都不是 设置 wb = ActiveWorkbook 环形 这个循环无休止地运行，直到我不得不手动取消它。 原来是设置 wb = workbooks.open(Test)

Private Sub UserForm_Initialize()
    Workbooks.Open Test, , , , , DynoCompPassword, True
    Set wb = ActiveWorkbook
    Set ws = wb.Worksheets("Info")
    Set ws = wb.Worksheets("Info")
    Set wsC = wb.Worksheets("Calipers")
    Set wsF = wb.Worksheets("Fixtures")
    Set wsW = wb.Worksheets("Wheel Sims")
    ws.Visible = True
    wsC.Visible = True
    wsF.Visible = True

btnCreate.Enabled = False
Dim rng As Range

lblLocation.Visible = False
tbLocation.Visible = False
Me.cbOut.AddItem "Sent To"
Me.cbOut.AddItem "Scrapped"
Me.cbOut.AddItem "Returned"
Me.btnCreate.Enabled = True

For Each rngprojectcode In ws.Range("ProjectCode")
    Me.cbProjectCode.AddItem rngprojectcode.Value
Next rngprojectcode

Set ProjCodeDictionary = New Dictionary 'Create the dictionary
Dim i As Integer
Dim j As Integer
Dim ProjCodeString As String
Dim AssociatedCodes As ProjectCodeList

If ws Is Nothing Then Exit Sub

    ProjCodeDictionary.CompareMode = vbTextCompare 'Make the .exists method case insensitive in an attempt to avoid duplicate values

    Set AssociatedCodes = New ProjectCodeList 'create the class module which will split up the associated codes into individual values
    i = 1
    While ws.Range("F1").Offset(i, 0) <> ""
        With AssociatedCodes
            .SetCodes = CStr(ws.Range("F1").Offset(i, 0).Value)
            For j = 1 To .NumCodes
                ProjCodeDictionary.Add .ProjCode(j), i 'key, item
            Next j
        End With
        i = i + 1
     Wend

If SelectedCompType = Fixture Then
    Me.lblCompNum.Caption = "Fixture ID"
    Me.btnCreate.Caption = "Update Fixture"
        'Automation Error occurs here
    Me.Caption = "Edit Fixture"
    Me.frChangeFrame.Height = 65
    Me.frChangeFrame.Caption = "Bolt Circle"
    Me.cbPartNum.Text = "FIX"
        For Each rng In wsF.Range("FixtureNum")
        Me.cbPartNum.AddItem rng.Value
        Next rng
    Set tbNumStuds = frChangeFrame.Controls.Add("Forms.TextBox.1", , "True")

为了澄清，只有在用户窗体中按下带有 X 的红色框时，才应激活 queryclose 子。它是用户窗体的内置函数。

Answer 1

queryclose 子程序唯一应该运行的时间是在用户窗体上按下 X 按钮时。

但这不是QueryClose 的工作方式。每当表单即将关闭时，UserForm.QueryClose 事件就会被触发，它的参数为您提供取消它的方法，具体取决于促使它关闭的原因。

当CloseMode 参数值为vbFormControlMenu（X 按钮 - 参见QueryClose constants）时，您想要有条件地运行wb.Close False：

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = vbFormControlMenu Then
        wb.Close False
    End If
End Sub

我尝试返回初始化子时代码[...]

不要这样做。事件处理程序旨在由 VBA 本身调用，而不是由用户代码调用。如果您需要调用已在事件处理程序中实现的逻辑，请将代码从处理程序中重构到它自己的过程中：

Private Sub UserForm_Initialize()
    DoInitializationStuff
End Sub

Private Sub DoInitializationStuff()
    '...
End Sub

最后，UserForm.Initialize 事件在表单显示之前被触发。

Set EditComp = New ufUpdateComp ' <~ initialize handler runs before this instruction returns
With EditComp
    .Top = Application.Top + 125
    .Left = Application.Left + 25
    .Show
End With

请注意，如果您只在 With 块中使用局部变量，则无需声明局部变量 - 让该块保留对象引用：

With New ufUpdateComp ' <~ initialize handler runs before this instruction returns
    .Top = Application.Top + 125
    .Left = Application.Left + 25
    .Show
End With

如果您希望DoInitializationStuff 在显示表单之后运行，请在Activate 事件中调用它。