从 SAS-EG 执行的 SAS 程序中的 SAS 触发错误

Question

如果不满足某个条件，我需要让 SAS 触发错误 我曾尝试使用 abort return n、abort abend 等。但它们似乎都 断开整个会话，我只想得到一个错误 用语法等。

这是一个 sas 程序，只能从 SAS-EG 以交互模式运行，并带有提示

我的代码：

DATA _NULL_;
IF prxmatch("/^TBDLZL\d{4}_[A-Z]/",&tablename_in) eq 0 then do;
    put "error table name &tablename_in does not match";
    ABORT RETURN 15; 
END;

RUN;

有什么建议吗？

Answer 1

你可以尝试使用：

put 'ERROR:' '/*customize error text here*/';

如果要停止执行数据步骤，可以使用stop 语句，例如：

DATA _NULL_;
   IF prxmatch("/^TBDLZL\d{4}_[A-Z]/",&tablename_in) eq 0 then do;
       put 'ERROR:' "table name &tablename_in" does not match;
       stop; 
   END;
RUN;

如果你有宏并且你想在宏执行步骤得到错误信息，你可以使用%put:

%put ERROR: /*customize error text here*/;

谢谢@Tom

请注意，仅当您对日志进行愚蠢搜索以查找错误时，才需要将单词 ERROR(put ‘ERR’ ‘OR:’...) 分成两部分的“技巧”。日志中的正常 SAS 错误消息始终出现在行首。例如，SAS/Studio 不会错误地将包含 ERROR 的程序行标记为实际错误。

感谢@MichaelKersten

多行注释、警告和错误的另一个巧妙技巧是 将第二行和连续行的“：”替换为“-”。 示例：

%put WARNING: first line of warning; 
%put WARNING- second line of warning;

Answer 2

使用ABORT CANCEL 语句。数据步骤将停止运行，提交代码中的以下步骤将不被处理。

例如：

data _null_;
  set sashelp.class;
  if name = "John" then do;
    put 'ERR' 'OR: My error message';
    abort cancel;
  end;
run;

* This step is not done due to earlier ABORT CANCEL;
data _null_;
  set sashelp.class;
  where name like 'J%';
run;

来自帮助：

取消
导致提交的语句的执行被取消。 操作取决于操作方法。

• 批处理模式和非交互模式

  • 终止整个 SAS 程序和 SAS 系统。
  • 将错误消息写入 SAS 日志。

• 窗口环境和交互线模式

  • 仅清除当前提交的程序。
  • 不影响其他后续提交的程序。
  • 将错误写入 SAS 日志。

• 工作区服务器和存储过程服务器

  • 仅清除当前提交的程序。
  • 不影响其他后续提交调用。
  • 将错误消息写入 SAS 日志。

• SAS IntrNet 应用服务器

  • 为每个请求创建单独的执行并提交 请求代码。请求代码中的 CANCEL 参数清除当前 提交代码但不终止执行或 SAS 会话。