在 VBS 脚本中使用 SAPI 语音识别？

Question

我发现了这个允许在 VBScript 中使用 Windows SAPI 文本到语音功能的单行示例：

CreateObject("SAPI.SpVoice").Speak("This is a test")

我想知道 SAPI 语音识别是否可以以同样简单的方式在 VBScript 程序中使用。当我寻找此类信息时，出现的大量 SAPI 信息与 C++ 相关，例如 Microsoft SAPI 站点或 VBS 中的文本到语音转换。我试图找到有关可在 VBScript 中使用的 SAPI COM 对象语音识别部分的文档，但没有找到。

你知道这样的文件是否存在吗？ TIA

编辑：在收到第一个答案后添加的附加请求

虽然下面的第一个答案提供了指向 SAPI COM 对象文档的链接，但我想提醒您注意我的问题中的一点：“我想知道 SAPI 语音识别是否可以在 VBScript 程序中使用 IN同样简单的方法”。 SAPI 文档巨大！我读了几页，我完全迷失了……我的目标是只识别几个单词，比如 8 或 10 个，并且每次识别其中一个单词时都会在屏幕上显示不同的信息；这就对了！ （该程序应该是通过cscript 启动的控制台应用程序）。是否有一个 简单 的 VBS 代码示例可以实现这样的事情？如果编写此解决方案所需的代码需要有几页，那么这不是我要寻找的答案...

Answer 1

这是一个vbscript 监听 wav 文件的工作示例：

scriptRunning = true

Sub rc_Recognition(StreamNumber, StreamPosition, RecognitionType, Result)
  Wscript.Echo "Reco: ", Result.PhraseInfo.GetText, ".", RecognitionType
End Sub

Sub rc_StartStream(StreamNumber, StreamPosition)
  Wscript.Echo "Start: ", StreamNumber, StreamPosition
End Sub

Sub rc_EndStream(StreamNumber, StreamPosition, StreamReleased)
  Wscript.Echo "End: ", StreamNumber, StreamPosition, StreamReleased
  scriptRunning = false
End Sub


outwav = "C:\SOFT\projects\af2t\t.wav"
Const SAFT22kHz16BitMono = 22
Const SSFMOpenForRead = 0

set sapiFStream = CreateObject("SAPI.SpFileStream")
sapiFStream.Format.Type = SAFT16kHz16BitMono
sapiFStream.Open outwav, SSFMOpenForRead


MsgBox "A SpeechLib::ISpRecoContext object will be created"

Const SGDSActive = 1

Set rct = WScript.CreateObject("SAPI.SpInProcRecoContext", "rc_")
Set rgnz = rct.Recognizer
Set rgnz.AudioInputStream = sapiFStream
Set rcGrammar = rct.CreateGrammar
'rcGrammar.DictationLoad
rcGrammar.DictationSetState SGDSActive
i = 0
while scriptRunning and i < 100
  WScript.Sleep(50)
  i = i + 1
wend

MsgBox "A SpeechLib::ISpRecoContext object has been created"

代码的神奇部分是这一行（“rc_”前缀参数允许事件被子捕获）：

Set rct = WScript.CreateObject("SAPI.SpInProcRecoContext", "rc_")

我用于测试的 t.wav 文件中的录制文本是使用 SAPI.SpVoice::Speak 和 MS-David 语音生成的；-)

我花了 10 天时间弄清楚如何编写这个脚本。微软正在删除有关自动化、COM、旧式脚本等的文档。真可惜。

所以，这可以在听写模式下读取 wav 文件。但我无法纠正它以使其在实时听写模式下工作（即使用麦克风作为直接输入）。对此表示赞赏的任何帮助。谢谢。

编辑：直接/实时听写模式已解决。如果有兴趣，我分享 vbscript 代码。

EDIT2： 以 wav 朗读的文本示例：Hello world. This is a talk about gear tooth profile using a circle involute. vbscript 的控制台输出

C:\SOFT\projects\af2t>cscript r.vbs
Microsoft (R) Windows Script Host Version 5.812
Copyright (C) Microsoft Corporation. Tous droits réservés.

Start:  1 0
Reco:  Hello world . 0
Reco:  this is a talk about gear to the profile using a circle invalid . 0
End:  1 195040 -1

C:\SOFT\projects\af2t>

Answer 2

是的。看SAPI Automation Overview；它会告诉你所有关于 VBScript 可用的后期绑定 COM 接口和对象。