读写二进制文件？

Question

我正在将一些自定义创建的对象类（流数据）保存到文件中。

我需要能够将文件的内容加载到 TStringList 中，这样我就可以在文件末尾追加一个新行，然后保存更改。

这不起作用，因为 LoadFromFile 似乎无法正确解析文件。我假设由于流保存到文件的有趣字符，并且 TStringList 需要纯文本信息。

我怎样才能做到以下几点：

• 将任何原始二进制文件读入 TStringList。
• 添加我的新行，例如 StringList1.Add(MyString);
• 再次保存原始二进制文件。

这个问题实际上与我问的另一个问题有关：Save a CRC value in a file, without altering the actual CRC Checksum?

这就是我想要做的：

• 计算我保存的流文件的 CRC 校验和。
• 将 CRC 值添加到文件末尾。
• 重新保存文件。

然后当我尝试打开我的流文件时：

• 将 CRC 值（位于文件末尾）分配给变量。
• 从文件中删除 CRC 值。
• 将流文件另存为新的临时文件。
• 计算并比较临时文件的 CRC，与存储在变量中的 CRC。
• 如果文件的 CRC 与内部存储的 CRC 值匹配，我可以正常处理文件。

但我不知道如何读取或写入文件的原始二进制数据。

如果有人能给我一些帮助和建议，我将不胜感激：)

Answer 1

此类从 TStringList 派生，并在写入文件时在末尾添加一个检查值。每当读取文件时都会检查此值。

type
  TCRCStringList = class(TStringList)
  type
    TCRC = LongWord;
  private
    function CalcCRC(Stream: TStream): TCRC;
  public
    procedure LoadFromStream(Stream: TStream; Encoding: TEncoding); override;
    procedure SaveToStream(Stream: TStream; Encoding: TEncoding); override;
  end;

function TCRCStringList.CalcCRC(Stream: TStream): TCRC;
begin
  Result := 42;  // place CRC calculation here
end;

procedure TCRCStringList.LoadFromStream(Stream: TStream; Encoding: TEncoding);
var
  crc: TCRC;
  temp: TMemoryStream;
begin
  temp := TMemoryStream.Create;
  try
    temp.CopyFrom(Stream, Stream.Size - Sizeof(crc));
    Stream.Read(crc, Sizeof(crc));
    if crc <> CalcCRC(temp) then
      raise Exception.Create('CRC error');
    temp.Position := 0;
    inherited LoadFromStream(temp, Encoding);
  finally
    temp.Free;
  end;
end;

procedure TCRCStringList.SaveToStream(Stream: TStream; Encoding: TEncoding);
var
  crc: TCRC;
  temp: TMemoryStream;
begin
  temp := TMemoryStream.Create;
  try
    inherited SaveToStream(temp, Encoding);
    temp.Position := 0;
    crc := CalcCRC(temp);
    temp.Position := temp.Size;
    temp.Write(crc, Sizeof(crc));
    Stream.CopyFrom(temp, 0); // count = 0 copies the whole stream from the beginning
  finally
    temp.Free;
  end;
end;