有条件地将子节点移动到属性

Question

我正在尝试转换此文档，但对 xslt 还很陌生，并且在尝试将其正确处理时获得了很多乐趣。核心节点（为简单起见被截断）如下所示

<Product prod_id="6352">
    <brandId>221</brandId>
    <brand>Oscar Mayer</brand>
    <images>
       <smallimage>text</simage>
       <medimage>text</medimage>
       <largeimage>text</limage>
    </images>
    <nutrition>
        <nutritionShow>Y</nutritionShow>
        <servingSize>1 SLICE</servingSize>
        <servingsPerContainer>12</servingsPerContainer>
        <totalCalories>60</totalCalories>
        <fatCalories>35</fatCalories>
        <totalFat>4</totalFat>
        <totalFatPercent>6</totalFatPercent>
        <totalFatUnit>g</totalFatUnit>
        <saturatedFat>1.5</saturatedFat>
        <saturatedFatPercent>8</saturatedFatPercent>
        <saturatedFatUnit>g</saturatedFatUnit>
        <transFat>0</transFat>
        <transFatUnit>g</transFatUnit>
        <cholesterolUnit>mg</cholesterolUnit>
    </nutrition>
    <prodId>6352</prodId>
</Product>

最后我想将逻辑分组的子节点作为具有适当属性名称的单个节点。

最终结果应该是这样的

<Product prod_id="6352">
<brandId>221</brandId>
<brand>Oscar Mayer</brand>
<images>
   <smallimage>text</smallimage>
   <medimage>text</medimage>
   <largeimage>text</largeimage>
</images>
<nutrition>
    <nutritionShow>Y</nutritionShow>
    <servingSize>1 SLICE</servingSize>
    <servingsPerContainer>12</servingsPerContainer>
    <totalCalories>60</totalCalories>
    <fatCalories>35</fatCalories>
    <totalFat amount="4" percent="6" unit="g" />
    <saturatedFat amount="1.5" percent="8" unit="g"/>
    <transFat amount="0" unit="g"</>
</nutrition>
<prodId>6352</prodId>

一些关键功能是

1. 对相似的属性进行分组（注意 saturatedFat 和 transFat ...略有不同）我有这些集合的离散列表。您可以使用列表或基于关系的更动态的东西，但请注意差异。
2. 保留其他（不可分组的）属性
3. 忽略缺少数量属性/只有单位属性的组（注意胆固醇）

提前感谢您帮助我理解这个相当复杂的转换。

Answer 1

一种可能的解决方案是遵循 XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" encoding="UTF-8" indent="yes" />
 <xsl:strip-space elements="*"/>
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="nutrition/*">
    <xsl:variable name="cName" select="name()"/>
    <xsl:choose>
      <xsl:when test="following-sibling::node()[name()=concat($cName,'Unit')]">
        <xsl:copy>
          <xsl:attribute name="amount">
            <xsl:value-of select="."/>
          </xsl:attribute>
          <xsl:if test="following-sibling::node()[name()=concat($cName,'Percent')]">
            <xsl:attribute name="percent">
              <xsl:value-of select="following-sibling::node()[name()=concat($cName,'Percent')]"/>
            </xsl:attribute>
          </xsl:if>
          <xsl:attribute name="unit">
            <xsl:value-of select="following-sibling::node()[name()=concat($cName,'Unit')]"/>
          </xsl:attribute> 
        </xsl:copy>
      </xsl:when>
      <xsl:when test="contains(name() ,'Unit') or contains(name() ,'Percent')"/>
      <xsl:otherwise>
        <xsl:copy>
          <xsl:apply-templates />
        </xsl:copy>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

当应用于您的输入 XML 时会产生输出

<Product prod_id="6352">
  <brandId>221</brandId>
  <brand>Oscar Mayer</brand>
  <images>
    <smallimage>text</smallimage>
    <medimage>text</medimage>
    <largeimage>text</largeimage>
  </images>
  <nutrition>
    <nutritionShow>Y</nutritionShow>
    <servingSize>1 SLICE</servingSize>
    <servingsPerContainer>12</servingsPerContainer>
    <totalCalories>60</totalCalories>
    <fatCalories>35</fatCalories>
    <totalFat amount="4" percent="6" unit="g"></totalFat>
    <saturatedFat amount="1.5" percent="8" unit="g"></saturatedFat>
    <transFat amount="0" unit="g"></transFat>
  </nutrition>
  <prodId>6352</prodId>
</Product>

第一个模板是Identity transform，它复制所有节点和属性而不做任何更改。
第二个模板匹配nutrition 的所有子元素/节点。
如果当前元素有一个本地名称与当前本地名称匹配并以 Unit 结尾的兄弟姐妹

<xsl:when test="following-sibling::node()[name()=concat($cName,'Unit')]">

当前节点必须是包含amount的节点。
当前节点的值写成amount属性的值

<xsl:attribute name="amount">
    <xsl:value-of select="."/>
</xsl:attribute>

如果存在匹配 Percent 的后续兄弟

<xsl:if test="following-sibling::node()[name()=concat($cName,'Percent')]">

Percent 属性是这样写的：

<xsl:attribute name="percent">
    <xsl:value-of select="following-sibling::node()[name()=concat($cName,'Percent')]"/>
  </xsl:attribute>

同样适用于Unit，无需事先检查是否存在匹配的Unit（如有必要，可以添加）。
空的

<xsl:when test="contains(name() ,'Unit') or contains(name() ,'Percent')"/>

删除已写入属性的Unit 和Percent 节点以及cholesterolUnit。
最后，所有其他不可分组的nutrition 元素都被复制：

<xsl:otherwise>
  <xsl:copy>
    <xsl:apply-templates/>
  </xsl:copy>
</xsl:otherwise> 

Answer 2

从 cmets 继续...

该示例显示了 3 种属性中的每一种。其他的如 一个人会期望...你看到饱和脂肪也可以期望 不饱和和单不饱和和多不饱和有5-12个 每个类别。类别为 1. 数量、单位和百分比 2. 数量 和单元 3. 独立

就我个人而言，我更喜欢将已知的事情拼写出来，因此对于给定的示例：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>


<!-- category #1: amount, unit and percent -->
<xsl:template match="totalFat">
    <totalFat amount="{.}" percent="{../totalFatPercent}" unit="{../totalFatUnit}" />
</xsl:template>

<xsl:template match="saturatedFat">
    <saturatedFat amount="{.}" percent="{../saturatedFatPercent}" unit="{../saturatedFatUnit}" />
</xsl:template>


<!-- category #2: amount and percent -->
<xsl:template match="transFat">
    <transFat amount="{.}" unit="{../transFatUnit}" />
</xsl:template>


<!-- suppress all units and percents -->
<xsl:template match="totalFatPercent | totalFatUnit | saturatedFatPercent | saturatedFatUnit | transFatUnit | cholesterolUnit | cholesterolPercent"/>

</xsl:stylesheet>

请注意，类别 #3 由 identity transform 模板处理，不需要例外。

---

另请注意，已知出现在每个产品中的项目不需要它们自己的模板；您可以在匹配nutrition 的模板中将它们写为文字结果元素，并将它们的名称添加到抑制的空模板中。