如何在perl中使用grep从一个数组中选择元素到另一个数组？

Question

我想捕捉CWD 中的文件和@files 中的文件之间的区别：

#!/usr/bin/perl -w
use Cwd qw[getcwd abs_path];
opendir CWD, getcwd;
@files=grep{!/^\./}readdir CWD;

push @files, ("foo.txt", "bar.txt");

for my $i (@files){
    @difference=grep { !/^\./ and $i!=$_ } readdir CWD;
}
print "$_\n" for @differenc 

现在当前目录有以下文件：

$ls
a.txt  e.txt  getopt.html

用这个表达式push @files, ("foo.txt", "bar.txt"); 该数组具有以下元素：("foo.txt", "bar.txt", "a.txt", "e.txt", "getopt.html")，这是正确的，但现在我只想选择那些在 CWD 中 not 的文件： @difference=grep { !/^\./ and $i!=$_ } readdir CWD;，所以我希望数组@difference 再次只有("foo.txt", "bar.txt")（我现在这没有意义，这是一个例子）。但是print什么都没有输出，怎么回事？

Answer 1

您在同一个文件句柄上有两个readdir 操作。一旦第一个到达 EOF，就不会再返回任何内容了。

在第二次迭代之前添加一个`rewinddir 操作。

Answer 2

你的代码有很多问题：

• 您的第二个readdir（在for my $i (@files) 循环中）没有读取任何内容，因为第一个（@files=grep{!/^\./}readdir CWD;）已经读取了整个目录。您可以先使用rewinddir，但只需使用@files 的副本（在推送foo.txt 和bar.txt 之前）会更简单、更高效。

• 您正在使用!= 而不是ne 来比较字符串。

• 循环的每次迭代都会删除@differences 的前一个值，因为您将它分配给=。大概push 会更有意义。

• 循环内部的逻辑有点缺陷。 grep 返回满足条件的元素，但你更感兴趣的是有没有满足条件的元素。

• 您应该检查opendir 是否成功（通过将or die ... 添加到opendir 行）。另外请注意，open my $CWD, getcwd 等价于更简单的open my $CWD, "."。

您可能想要做的是：

use strict;
use warnings;

opendir my $CWD, "." or die "Could not open '.': $!";

my @files = grep{!/^\./} readdir $CWD;
my @init_files = @files;

push @files, ("foo.txt", "bar.txt");

my @difference;
for my $i (@files){
    push @difference, (grep { !/^\./ and $i eq $_ } @init_files) ? () : $i;
}
print "$_\n" for @difference

然而，这远非高效，而且需要更加复杂。我建议改为：

my %files = map { $_ => 1 } grep {!/^\./} readdir $CWD;

my @difference;
for ("foo.txt", "bar.txt") {
    push @difference, $_ if ! exists $files{$_};
}
print "$_\n" for @difference

请注意，我已将 use strict; use warnings; 添加到脚本中。始终将它们添加到您的代码中。虽然在这种特定情况下，它不会帮助您找出问题所在，但它会在未来为您节省无数小时。此外，始终使用词法文件/目录句柄（即使用opendir my $CWD, "dir" 而不是open CWD, "dir"）。