检测一组 WPF 控件丢失的焦点答案

【问题标题】：Detect focus lost from a group of WPF controls检测一组 WPF 控件丢失的焦点
【发布时间】：2012-11-12 04:41:24
【问题描述】：

我正在使用具有可编辑内容的代码构建一个 GUI。当用户单击静态显示时，控件将换成允许编辑的控件。在某些情况下，显示控件（例如Label）会被替换为一组控件，例如ComboBox 和TextBox。

我想检测我的可编辑控件组何时失去焦点，以便将界面从编辑器切换回该项目的显示表示。

例如，我可能在 Panel1(Panel2(Button1, Button2), Button3) 这样的树中有一个 GUI，我想检测何时从 Panel2 失去焦点。我尝试了以下（F# 代码）：

open System.Windows

let button1 = Controls.Button(Content="1")
let button2 = Controls.Button(Content="2")
let button3 = Controls.Button(Content="3")

[<System.STAThreadAttribute>]
do
  let panel1 = Controls.StackPanel()
  let panel2 = Controls.StackPanel()
  panel2.Children.Add button1 |> ignore
  panel2.Children.Add button2 |> ignore
  panel1.Children.Add panel2 |> ignore
  panel1.Children.Add button3 |> ignore
  panel2.LostFocus.Add(fun _ ->
    printfn "Panel2 lost focus")
  Application().Run(Window(Content=panel1))
  |> ignore

button3 在点击button2 后被点击时触发panel2.LostFocus 事件，正如预期的那样，因为焦点从panel1 移到button3。但是，即使panel2 从未失去焦点，在点击button1 之后点击button2 也会触发它。

阅读有关 WPF 中焦点的 MSDN 文档，我尝试添加：

Input.FocusManager.SetIsFocusScope(panel2, true)

但这实际上使问题变得更糟！现在panel2.LostFocus 事件仅在焦点从panel2 的一个子级转移到另一个子级时触发，而不是在panel2 实际失去焦点时触发。

我应该如何获得想要的效果？

【问题讨论】：

标签： c# wpf f# focus

【解决方案1】：

感谢 Twitter 上的 Ian Voyce，我能够使用 IsKeyboardFocusWithinChanged 事件获得所需的功能。这是一个演示：

open System.Windows

let Button x =
  Controls.Button(Content=x, Width=64.0, Margin=Thickness 3.0)

let Panel ctrls =
  let panel = Controls.StackPanel()
  for ctrl in ctrls do
    panel.Children.Add ctrl
    |> ignore
  panel

let label = Controls.Label(Content="Edit 12")
let button1 = Button "1"
let button2 = Button "2"
let button3 = Button "3"

let panel = Panel[button1; button2]

[<System.STAThreadAttribute>]
do
  label.HorizontalContentAlignment <- HorizontalAlignment.Center
  label.MouseLeftButtonDown.Add(fun _ ->
    label.Content <- panel)
  panel.IsKeyboardFocusWithinChanged.Add(fun e ->
    if not(unbox e.NewValue) then
      label.Content <- "Edit 12")
  Application().Run(Window(Content=Panel[label :> UIElement; button3 :> UIElement]))
  |> ignore

【讨论】：