XSLT 函数返回不同的结果 [Saxon-EE vs Saxon-HE/PE]

Question

我目前正在使用各种版本的 Saxon-Processor 进行纯 XSL 转换。下面是我的简短样式表，根据我的问题进行了简化：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:foo="bar">

    <xsl:output encoding="UTF-8" method="text"/>

    <xsl:template match="/">
        <xsl:text>Call of func_1: </xsl:text>        
        <xsl:value-of select="foo:func_1()"/>

        <xsl:text>&#xA;Call of func_1: </xsl:text>
        <xsl:value-of select="foo:func_1()"/>

        <xsl:text>&#xA;Call of func_1: </xsl:text>
        <xsl:value-of select="foo:func_1()"/>

        <xsl:text>&#xA;Call of func_2: </xsl:text>
        <xsl:value-of select="foo:func_2()"/>
    </xsl:template>

    <xsl:function name="foo:func_1" as="xs:string">
        <!-- do some other stuff -->
        <xsl:value-of select="foo:func_2()"/>
    </xsl:function>

    <xsl:function name="foo:func_2" as="xs:string">
        <xsl:variable name="node">
            <xsl:comment/>
        </xsl:variable>
        <xsl:sequence select="generate-id($node)"/>
    </xsl:function>

</xsl:stylesheet>

说明

foo:func_1 是一个包装函数，用于返回第二个函数的值 + 做其他事情，可以忽略。这个函数调用其他函数的概念是强制性的！

foo:func_2 为元素生成一个唯一的 id。该元素是在名为“node”的局部范围变量中创建的。

基于撒克逊版本的不同结果

预期结果：

Call of func_1: d2
Call of func_1: d3
Call of func_1: d4
Call of func_2: d5

Saxon-EE 9.6.0.7 / Saxon-EE 9.6.0.5 结果

Call of func_1: d2
Call of func_1: d2
Call of func_1: d2
Call of func_2: d3

Saxon-HE 9.6.0.5 / Saxon-PE 9.6.0.5 / Saxon-EE 9.5.1.6 / Saxon-HE 9.5.1.6 结果

like expected

问题/进一步深入

我尽可能自己调试问题。如果我将函数“func_1”中的xsl:value-of 更改为xsl:sequence，则所有版本的结果都将相同[如预期的那样]。但这不是我的本意！

我想了解，撒克逊版本中xsl:value-of 和xsl:sequence 之间有什么区别。 是否有任何“隐藏”缓存？在我的情况下，使用 xsl:sequence 和 xsl:value-of 的正确方法是什么。 [顺便说一句：我已经知道，value-of 使用 select 语句的结果创建了一个文本节点。序列可以是对节点或原子值的引用。不要解决我的问题 afaik]

Answer 1

这是一个长期存在且相当深刻的问题。在纯函数式语言中，使用相同的参数调用纯函数两次总是会产生相同的结果。这使得许多优化成为可能，例如如果参数不变，则将函数调用拉出循环，或者如果函数调用不是递归的，则内联函数调用。不幸的是，XSLT 和 XQuery 函数并不完全是函数式的：特别是，它们被定义为如果函数创建新节点，则调用该函数两次会产生不同的节点（f() is f() 返回 false）。

Saxon 优化器非常努力地在这些约束范围内尽可能地进行优化，特别是通过识别创建新节点的函数并避免对此类函数进行激进的优化。

但规范本身并不是 100% 规定的。例如，如果在您的示例中存在一个不依赖于函数参数的局部变量，我认为规范允许实现该变量的值是每次评估时的相同节点还是新节点.

正如 Martin 所说，新的 XSLT 3.0 属性 new-each-time 试图控制这种情况：如果您真的希望每次调用函数时都有一个新节点，您应该指定 new-each-time="yes"。

注意：

这里发生的具体优化（您可以通过运行 -explain 选项看到）是首先内联 func_2，然后将其主体提取到全局变量中。一些版本正在这样做，而其他版本则没有——它可能对微小的变化非常敏感。最好的建议是不要依赖具有这种副作用的函数。如果您解释了您的真正问题会有所帮助，那么也许我们可以找到一种对语言语义中的边缘情况不太敏感的方法。