【问题标题】:Modified 6502 Interrupt Returns修改的 6502 中断返回
【发布时间】:2016-05-11 22:59:05
【问题描述】:

我正在尝试在中断返回时切换正常的程序流程:

START
    SEI
    LDX #<IRQ
    LDY #>IRQ
    STX $FFFE
    STY $FFFF
    CLI

LOOP1
    INC $D020
    JMP LOOP1

LOOP2
    INC $D021
    JMP LOOP2

IRQ
    STA SAVEA+1
    STX SAVEX+1
    STY SAVEY+1

    // Some Routines

    LDA #$00
    PHA
    LDA #<LOOP2
    PHA
    LDA #>LOOP2
    PHA

SAVEA   
    LDA #$00
SAVEX   
    LDX #$00
SAVEY   
    LDY #$00
    RTI

我根据该来源编写了这段代码: http://6502.org/tutorials/interrupts.html#1.3

但是PHA会导致崩溃,如何在中断中将正常流程LOOP1切换到LOOP2?

【问题讨论】:

  • @DavidHoelzer 你误解了代码,那部分只是设置中断,两个循环是他要调度的两个进程。也就是说,在处理程序中禁用进一步的中断听起来是个好主意。此外,应该删除已经保存在堆栈上的东西,否则如果你继续推东西,你会得到堆栈溢出。顺序好像也错了,需要和图上的一样。
  • 哦,是的,你是对的。我忽略了 IRQ 代码的 。已经有一段时间了。 :)
  • 目前还不清楚您是在尝试操作堆栈内容还是编写自修改代码。您推送了一个新的退货地址,但之前的地址仍然存在。您将很快耗尽堆栈。我建议PHA; TXA; PHA; TSX,然后通过索引X 修改堆栈返回地址,然后恢复寄存器并执行RTI。
  • 您确实意识到这样做很可能会导致非常意想不到的结果,除了最简单的例程(如循环),不使用寄存器、堆栈或状态标志,除了可以被随时有其他例行程序?您最好在中断处理程序内的内存中设置一些标志,并在循环内对该值执行受控检查并相应地分支。

标签: assembly 6502 c64


【解决方案1】:

最简单的事情可能是有两个堆栈区域——每个任务一个。例如,$100-$17f 和 $180-$1ff。 然后,你的中断任务切换代码如下:

  pha
  txa
  pha
  tya
  pha ;saving task's registers on its stack,
      ;where flags and PC are already saved
      ;by entering the interrupt

  tsx
  stx ... ;save task's stack position

  ... ;select new task to run/etc.

  ldx ...
  txs ;load other task's stack position

  pla
  tay
  pla
  tax
  pla ;restore other task's registers

  rti ;and finally continue other task 

【讨论】:

  • 这是一种巧妙的方法。也许值得指出硬件没有强制执行任何堆栈边界。因此,如果 B 最终进入 A 堆栈空间,A 可能会开始做一些非常奇怪的事情。任务切换器可以进行一些范围完整性检查。但是一些环绕错误仍然无法检测到。
  • @lvd,TSX 是我在下面写的解决方案的关键,我测试过,它有效!谢谢!
  • 硬件一般不强制堆栈边界;唯一的区别是限制是 128 字节而不是 256 字节,如果你默默地超出,你会踩到别人的栈顶而不是你自己的栈顶。
【解决方案2】:

简单的方法是:

TSX
LDA #$00
STA $0101,X   // Processor Status
LDA #<LOOP2
STA $0102,X   // Task Low Address
LDA #>LOOP2
STA $0103,X   // Task High Address

但对于更复杂的任务管理,我们必须为每个任务保存 A,X,Y 寄存器:

START
    SEI
    LDX #<IRQ
    LDY #>IRQ
    STX $FFFE
    STY $FFFF
    CLI

LOOP1
    INC $D020
    JMP LOOP1

LOOP2
    INC $D021
    JMP LOOP2

IRQ
    STA $FF
    STX $FE
    STY $FD
    LDX TASK+1
    CPX TASK
    BEQ CONT
    LDY TASKI,X
    TSX
    LDA $0101,X
    STA TASKS+0,Y
    LDA $0102,X
    STA TASKS+1,Y
    LDA $0103,X
    STA TASKS+2,Y
    LDA $FF
    STA TASKS+3,Y
    LDA $FE
    STA TASKS+4,Y
    LDA $FD
    STA TASKS+5,Y
    LDA TASK
    STA TASK+1
CONT

    // Change Task
    LDA TASK
    CLC
    ADC #$01
    AND #$01
    STA TASK


    LDX TASK
    CPX TASK+1
    BEQ CONT2
    STX TASK+1
    LDY TASKI,X
    TSX
    LDA TASKS+0,Y
    STA $0101,X
    LDA TASKS+1,Y
    STA $0102,X
    LDA TASKS+2,Y
    STA $0103,X
    LDA TASKS+3,Y
    STA $FF
    LDA TASKS+4,Y
    STA $FE
    LDA TASKS+5,Y
    STA $FD
CONT2
    LDA $FF
    LDX $FE
    LDY $FD
    RTI

TASK
    .BYTE 0,0
TASKI
    .BYTE 0,6,12,18,24,30,36
TASKS
    .BYTE 0,<LOOP1,>LOOP1,0,0,0
    .BYTE 0,<LOOP2,>LOOP2,0,0,0

【讨论】:

  • 当堆栈恰好从 $100 回绕到 $1ff 时,tsx:lda $101,x:etc. 代码不会有问题吗?可能不适用于您仔细划分堆栈空间的情况,但一般来说,如果堆栈仅用于中断堆栈、过程调用和最终的 PHA/PLA,则根本不需要担心确切的堆栈位置。
猜你喜欢
  • 2012-07-07
  • 2019-11-10
  • 1970-01-01
  • 1970-01-01
  • 2020-06-07
  • 2016-08-03
  • 2023-03-25
  • 1970-01-01
  • 2013-10-22
相关资源
最近更新 更多