执行子进程：将 PYTHONPATH 传递给子进程

Question

当我执行 Python 脚本并确保正确设置 PYTHONPATH 以引用依赖模块时。在 Python 代码中，我调用了一个 TCL 脚本，该脚本再次调用如下 Python 脚本：

if {[catch {exec {*}[auto_execok python] [file nativename [file join [file dirname [info script]] my.py ]] } result] == 0 } {
     puts "Executed successfully $result"
 } else {
     puts "Error $result"
     return error
}

我能够成功地在外部执行 Python 脚本 my.py，但是从 TCL 脚本执行时会出现问题。不知何故，我发现这是因为调用 Python 脚本时 PYTHONPATH 未正确传递，因为 my.py 引用了依赖 Python 模块。

如何在 exec 命令中传递 PYTHONPATH？

Answer 1

PYTHONPATH 是一个环境变量。它们通过env 全局变量进行操作：

# You might be able to set this once for your whole script
set python_path {C:/Python/3.6/wherever C:/Users/me/Python/3.6/wherever}
# Transform a Tcl list into the right format that Python expects
set ::env(PYTHONPATH) [join [lmap p $python_path {file nativename $p}] \
    $::tcl_platform(pathSeparator)]

# Split this out for a shorter line length. ;-)
set my_py [file join [file dirname [info script]] my.py]

if {[catch {exec {*}[auto_execok python] [file nativename $my_py]} result] == 0 } {
    puts "Executed successfully $result"
} else {
    puts "Error $result"
    return error
}

在 Tcl 8.5 中，您没有 lmap 或 tcl_platform 的 pathSeparator 元素，而是会执行以下操作：

foreach p $python_path {
    if {[info exist ::env(PYTHONPATH)]} {
        # Assume Windows
        append ::env(PYTHONPATH) ";" [file nativename $p]
    } else {
        set ::env(PYTHONPATH) [file nativename $p]
    }
}

如果它们只是一两个元素，您也可以对这些值进行硬编码。请记住，反斜杠 (\) 对 Tcl 很重要，因此如果您这样做，请将字符串放入 {...}。

set ::env(PYTHONPATH) {C:\Python\3.6\wherever;C:\Users\me\Python\3.6\wherever}

这对于任何可再分发的东西都不是特别可行……但适用于自己的脚本。