.bat 测量文件路径长度并将其放入 .txt 文件中

Question

我正在尝试制作一个 .bat 文件，该文件将遍历给定文件夹中的所有文件，测量文件+路径的长度以及它是否比例如长。文件和路径的 50 个字符被写入 .txt 文件。

我几乎是一个 n00b，所以不高级，而且解释得很好；）。

我正在写入一个文件

echo %File% > filer.txt

其中 File 应包含文件名和路径。

编辑： 对不起，我对它应该执行的任务的描述可能有点不清楚。我要说的是，循环遍历给定文件夹的文件和子文件夹。并在文档中返回路径超过 50 的文件，包括 Drive 和 Filetype。

Answer 1

正如 Dennis 已经指出的，批处理没有用于获取路径长度的内置解决方案。但如果你只想知道，如果一个字符串大于n，只需检查n+1位置是否有字符：

if "%string:~51,1%" neq "" echo %string% is longer than 50 characters

比计算字符快得多。

结合丹尼斯的逻辑：

@echo off
setlocal EnableDelayedExpansion
(
  for %%g in ("*") do (
    set "File=%%~dpnxg"
    if "!File:~51,1!" neq "" echo !File!
  )
)>filer.txt

我把整个for 循环放到另一个块中，只重定向一次到输出文件。这要快得多（>> 会打开文件，写一行并关闭文件，然后再次打开它等等......）

Answer 2

你可以用这个：

@echo off
setlocal EnableDelayedExpansion
for %%g in ("*") do (
set "File=%%~dpnxg"
>x echo !File!&for %%? in (x) do set /a strlength=%%~z? - 2&del x
if !strlength! gtr 50 echo !File! >> filer.txt
)

这将遍历当前文件夹中的所有文件，并将它们的驱动器、路径、名称和扩展名放入变量%File%。然后它将%File% 写入临时文件x，并从中获取字符串长度，然后删除x。如果字符串长度大于 50，它会将文件名写入filer.txt。

您需要delayed expansion 才能处理循环内的变量。

注意，此代码当前使用驱动器、路径、文件名和扩展名。更改行 set "File=%%~dpnxg" 以更改此行为（[d]rive, [p]ath, [n]ame, e[x]tension，g 是必要的）