列出本地硬盘驱动器的批处理脚本，然后在每个驱动器上执行 dir 命令

Question

我试图根据这个主题制作一个脚本

batch script to find drive letter of a mounted device

但没有真正的成功。

这是脚本：

SETLOCAL EnableDelayedExpansion
for /f "usebackq tokens=1,*" %%i in (`fsutil fsinfo drives`) do (
    if exist %%j dir /S /D "%%j*hurrdurr.txt" >> fud_india.com_%computername%.txt
)
pause

问题是我得到了结果，但仅适用于 1 个驱动器号...

有人可以帮忙吗？

Answer 1

@echo off
    setlocal enableextensions disabledelayedexpansion

    >"fud_india.com_%computername%.txt" 2>nul (
        for /f "delims=: tokens=1,*" %%a in ('fsutil fsinfo drives') do (
            for %%c in (%%b) do vol %%~dc && dir /s /d "%%~dc\hurrdurr.txt"
        )
    ) 

for /f 只处理行，在这种情况下是fsutil 命令的输出，并且能够使用指定的分隔符集将这些行拆分为标记。 fsutil 在一行中返回所有驱动器，类似于

Drives: C:\ D:\ E:\

在不知道有多少个驱动器可以排成一行的情况下，我们无法（或多或少）指明我们想要多少个令牌。因此，我们需要获取行，分离标题，获取列表并遍历列表中的元素（驱动器）

第一步是将标题与驱动器列表分开。这是通过tokens 和delims 子句在for /f %%a 中直接完成的。我们将使用冒号作为分隔符来分割标记中的行。

我们请求两个标记：第一个标记 (%%a) 将存储文本直到第一个分隔符（标题），第二个标记 (%%b) 将存储该行的其余部分（这就是* 表示在令牌子句中）

使用存储在%%b 中的驱动器列表，我们需要一种方法来迭代它。这就是for %%c in (%%b) ... 的原因。当%%b 展开时，生成的命令将是

for %%c in (C:\ D:\ E:\) do ...

对于列表中的每个元素，vol 命令用于确定驱动器是否可用，如果未设置错误级别，则执行dir 命令。

由于vol命令只接受一个驱动器引用，没有路径，我们需要从列表中的元素中去掉结尾的反斜杠，所以我们不直接使用%%c，而是使用%%~dc，即， %%c 中引用的元素的驱动器。

完整的for 循环用括号括起来并重定向，因此输出文件只需打开/关闭一次。

Answer 2

你的%%j包含C:\ D:\ E:\ F:\ G:（对我来说），这就是你的if：

if exist C:\ D:\ E:\ F:\ G:\ dir ...

显然语法错误。

我建议另一种方法（wmic）：

for /f "skip=1" %%i in ('wmic logicaldisk get caption') do (
  dir /s /d %%i\*hurrdurr.txt" >>fud_india.com_%computername%.txt 2>nul
)

通过摆脱if exist，您可以避免GUI-Box“无媒体”； >nul 只是将 dir-error 发送到 nirvana。