批处理脚本 - 更改桌面上文件夹的图标 (Windows XP)答案

【问题标题】：Batch Script - Change Icon of a Folder on Desktop (Windows XP)批处理脚本 - 更改桌面上文件夹的图标 (Windows XP)
【发布时间】：2011-09-10 04:26:30
【问题描述】：

如何通过 windows xp 中的命令行/批处理脚本更改桌面文件夹的图标/图像？

我将在我的一个脚本中创建一个事件，以便在将新文件插入文件夹时将图标更改为感叹号的图像以提醒用户。

【问题讨论】：

如果您能阐明显示此文件夹图标的上下文，将会有所帮助。是桌面还是网页，什么操作系统？
Windows XP 与桌面图标有关。我将编辑问题

标签： command-line windows-xp batch-file icons directory

【解决方案1】：

将您的 image.ico 保存到桌面。
以下将在桌面上创建一个测试文件夹以及链接您要使用的图像文件的 desktop.ini 文件。

CD "%userprofile%\desktop"
MKDIR "TEST FOLDER"
ATTRIB +s "TEST FOLDER"
CD "TEST FOLDER"
COPY /Y "%userprofile%\desktop\image.ico" "./image.ico"
ECHO [.ShellClassInfo] >> desktop.txt
ECHO ConfirmFileOp=0 >> desktop.txt
ECHO NoSharing=1 >> desktop.txt
ECHO IconFile=image.ico >> desktop.txt
ECHO IconIndex=0 >> desktop.txt
ECHO InfoTip= >> desktop.txt
CHCP 1252 >NUL
CMD.EXE /D /A /C (SET/P=ÿþ)<NUL > desktop.ini 2>NUL
CMD.EXE /D /U /C TYPE desktop.txt >> desktop.ini
DEL /F /Q desktop.txt
ATTRIB +S +H desktop.ini image.ico

只要是新文件夹（不是已删除并重新创建的文件夹），图像就会立即显示。您只需“mkdir”一个最近删除的文件夹，需要刷新桌面才能看到更改（缓存?)。

【讨论】：

那是一些严肃的魔法。非常有帮助。谢谢！
那么，要对现有文件夹执行此操作，您只需 mkdir newstuff && rmdir newstuff 就可以强制刷新桌面？
感谢您的回答。请更正第五行的错字：%userprofile%。尝试自己做，但愚蠢的“编辑必须超过 6 个字符”规则阻碍了。
这条线做什么CMD.EXE /D /A /C (SET/P=ÿþ)<NUL > desktop.ini 2>NUL？

【解决方案2】：

您应该将 desktop.ini 文件放在文件夹中。看这里

http://perishablepress.com/press/2006/10/16/folder-background-images-in-winxp/

http://msdn.microsoft.com/en-us/library/cc144102(v=vs.85).aspx

【讨论】：

微软链接 =D

【解决方案3】：

“Mechaflash”的回答在我的系统（Windows XP SP3）上对我不起作用。 . .但这有效：
打开一个工作文件夹并在其中放置一个图标（“Desktop.ini.ico”）和这个批处理文件：

@ECHO OFF  
PUSHD "%~dp0"  
MKDIR "NEW CUSTOM FOLDER"  
ATTRIB -R "NEW CUSTOM FOLDER"  
ATTRIB -H -R "NEW CUSTOM FOLDER\Desktop.ini.ico"  
ATTRIB -H -R "NEW CUSTOM FOLDER\Desktop.ini"  
COPY /Y "Desktop.ini.ico" "NEW CUSTOM FOLDER\Desktop.ini.ico"  
ECHO [.ShellClassInfo] > "NEW CUSTOM FOLDER\Desktop.ini"  
ECHO IconFile=Desktop.ini.ico >> "NEW CUSTOM FOLDER\Desktop.ini"  
ECHO IconIndex=0 >> "NEW CUSTOM FOLDER\Desktop.ini"  
ECHO InfoTip=This folder InfoTip text is inside "Desktop.ini" >> "NEW CUSTOM FOLDER\Desktop.ini"  
ATTRIB +H +R "NEW CUSTOM FOLDER\Desktop.ini.ico"  
ATTRIB +H +R "NEW CUSTOM FOLDER\Desktop.ini"  
ATTRIB +R "NEW CUSTOM FOLDER"  
POPD  
EXIT

双击批处理文件，瞧，您的工作文件夹中有“新自定义文件夹”。

【讨论】：