批处理文件 CSV 字符串到金字塔

Question

我正在处理其中一个批处理文件，并且我有一个特定要求，我有一个字符串 "text1,text2,text3,text4...etc" 并且我想拥有我的输出为像

这样的金字塔

文本1
文本1，文本2
文本1，文本2，文本3
文本 1、文本 2、文本 3、文本 4
..等

我的大脑说这很容易实现，但不明白逻辑！我怎么能通过批处理脚本（for循环）来做到这一点？

Answer 1

下面的方法允许您拥有一个逗号分隔值列表，其中可能包含空格或批处理特殊字符。当然，它也适用于您的简单值。

@echo off
setlocal EnableDelayedExpansion

set "string=text one,text <two>,text |three|,text &four&"
set "line="
for %%a in ("%string:,=","%") do (
   set "line=!line!%%~a,"
   echo !line:~0,-1!
)

输出：

text one
text one,text <two>
text one,text <two>,text |three|
text one,text <two>,text |three|,text &four&

Answer 2

@echo off
    setlocal enableextensions enabledelayedexpansion

    set "text=text1,text2,text3,text4,text5,text6,text7,text8"
    set "output="

    for %%a in (%text%) do (
        if defined output ( set "output=!output!,%%a" ) else set "output=%%a"
        echo(!output!
    )

由于值用逗号分隔，并且逗号是for 命令中的默认分隔符，因此只需在处理这些值时迭代连​​接这些值的列表

Answer 3

您可以使用一个变量，在每个循环中，您都将在其上附加一个文本。您还需要激活delayedexpansion，以便您的变量快速更新。 for /l %%a in (;;) 创建一个无限循环。

@echo off
setlocal enabledelayedexpansion
set var=text1
for /l %%a in (;;) do (
    echo !var!
    set var=!var!,text1
)

编辑：注意到您的数字实际上是递增的。你可以这样做：

@echo off
setlocal enabledelayedexpansion
set var=text1
for /l %%a in (2,1,100) do (
    echo !var!
    set var=!var!,text%%a
)

• 2 = %%a 的初始值
• 1 = 每个循环的增量
• 100 = 最大数量，但仅与条件有关。打印的最大数量为 100 - 1 或 99。