XSLT 标记 N 值以标记一个值答案

【问题标题】：XSLT Tag with N Values to Tag with One ValueXSLT 标记 N 值以标记一个值
【发布时间】：2014-12-05 02:20:09
【问题描述】：

我下面有这种情况：

<GetNewOrdersResponse>
  <GetNewOrdersResult>
    <Receipts>
      <IdOrder>1</IdOrder>
      <IdOrder>2</IdOrder>
      <IdOrder>3</IdOrder>
    </Receipts>
  </GetNewOrdersResult>
</GetNewOrdersResponse>

而我想转变成这种结构

<GetNewOrdersResponse>
  <GetNewOrdersResult>
    <Receipts>
      <IdOrder>1</IdOrder>
    </Receipts>
    <Receipts>
      <IdOrder>2</IdOrder>
    </Receipts>
    <Receipts>
      <IdOrder>3</IdOrder>
    </Receipts>
  </GetNewOrdersResult>
</GetNewOrdersResponse>

我试过这段代码，但没有成功：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" indent="yes"/>
  <xsl:template match="/">
    <ns0:Test xmlns:ns0="http://test/GetNewOrders">
      <GetNewOrdersResponse>
        <GetNewOrdersResult>
          <Receipts>
            <IdOrder>
            <xsl:for-each select="GetNewOrdersResponse/GetNewOrdersResult/Receipts/IdOrder">
              <xsl:value-of select="IdOrder"/>
            </xsl:for-each>
            </IdOrder>
          </Receipts>
        </GetNewOrdersResult>
      </GetNewOrdersResponse>
    </ns0:Test>
  </xsl:template>
</xsl:stylesheet>

【问题讨论】：

为什么你的代码有这个：<ns0:Test xmlns:ns0="http://test/GetNewOrders">？我在您的预期结果中没有看到类似的内容。

标签： xml xslt transformation

【解决方案1】：

这是相当简单的，使用身份转换模板作为规则和一些例外的规则：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Receipts">
    <xsl:apply-templates select="@*|node()"/>
</xsl:template>

<xsl:template match="IdOrder">
    <Receipts>
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </Receipts>
</xsl:template>

</xsl:stylesheet>

或者，如果您更喜欢尝试的逻辑：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/">
    <GetNewOrdersResponse>
        <GetNewOrdersResult>
            <xsl:for-each select="GetNewOrdersResponse/GetNewOrdersResult/Receipts/IdOrder">
                <Receipts>
                    <xsl:copy-of select="."/>
                </Receipts>
            </xsl:for-each>
        </GetNewOrdersResult>
    </GetNewOrdersResponse>
</xsl:template>

</xsl:stylesheet>

【讨论】：

迈克尔，感谢您的快速回复。我是 XSL 的新手，这对我很有帮助，非常感谢。