有没有办法合并多个 XSLT 以在单个输出文件中获得输出？答案

【问题标题】：Is there a way to merge multiple XSLT’s to get output in a single output file?有没有办法合并多个 XSLT 以在单个输出文件中获得输出？
【发布时间】：2020-12-03 14:27:58
【问题描述】：

我目前有一个开发项目，它从单个 XML 输入生成三个不同的员工状态的三个不同文件。以下是示例 XML。

 <wd:Report_Data xmlns:wd="urn:com.workday.report/Demo_Report">
 <wd:Report_Entry>
 <wd:Flag>HIRE</wd:Flag>
 <wd:Userid>12345</wd:Userid>
 <wd:FirstName>Jack</wd:FirstName>
 <wd:LastName>Jones</wd:LastName>
 <wd:BusinessTitle>Engineer</wd:businessTitle>
 <wd:Country>US</wd:Country>
 </wd:Report_Entry>
 <wd:Report_Entry>
 <wd:Flag>UPDATE</wd:Flag>
 <wd:Userid>890767</wd:Userid>
 <wd:FirstName>Mike</wd:FirstName>
 <wd:LastName>Balder</wd:LastName>
 <wd:BusinessTitle>Jr.Engineer</wd:businessTitle>
 <wd:Country>US</wd:Country>
 </wd:Report_Entry>
 <wd:Report_Entry>
 <wd:Flag>TERMINATE</wd:Flag>
 <wd:Userid>543908</wd:Userid>
 <wd:FirstName>Bolton</wd:FirstName>
 <wd:LastName>James</wd:LastName>
 <wd:BusinessTitle>Sr.Engineer</wd:businessTitle>
 <wd:Country>US</wd:Country>
 </wd:Report_Entry>
 </wd:Report_Data>

我有以下三个 XSLT，它们生成三个不同员工状态的文件，如下所示。

XSLT 1

     <?xml version="1.0" encoding="UTF-8"?>
     <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
     xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" 
     xmlns:xtt="urn:com.workday/xtt" xmlns:wd="urn:com.workday.report/Demo_Report" 
     xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" version="2.0">
     <xsl:output method="text"/>
     <xsl:variable name="linefeed" select="'&#xA;'"/>
     <xsl:template match="wd:Report_Data">
     <File>
      <xsl:text>user,add,abc@y.com,admin,ghy567</xsl:text>
      <xsl:value-of select="$linefeed"/>
      <xsl:text>"User id","FirstName","LastName","BusinessTitle","Country"</xsl:text>
      <xsl:value-of select="$linefeed"/>
      <!--  for each Employee section -->
      <xsl:for-each select="/wd:Report_Data/wd:Report_Entry">
      <xsl:if test="wd:Flag ='HIRE' and wd:Position Type !=''">
      <xsl:text>"</xsl:text>
      <xsl:value-of select="wd:Userid"/>
      <xsl:text>","</xsl:text>
      <xsl:value-of select="wd:FirstName"/>
      <xsl:text>","</xsl:text>
      <xsl:value-of select="wd:LastName"/>
      <xsl:text>","</xsl:text>
      <xsl:value-of select="wd:BusinessTitle"/>
      <xsl:text>","</xsl:text>
      <xsl:value-of select="wd:Country"/>
      </xsl:if>
      </xsl:for-each>
      </File>
      </xsl:template>
      </xsl:stylesheet>

XSLT 2

     <?xml version="1.0" encoding="UTF-8"?>
     <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
     xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" 
     xmlns:xtt="urn:com.workday/xtt" xmlns:wd="urn:com.workday.report/Demo_Report" 
     xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" version="2.0">
     <xsl:output method="text"/>
     <xsl:variable name="linefeed" select="'&#xA;'"/>
     <xsl:template match="wd:Report_Data">
     <File>
      <xsl:text>user,update,abc@y.com,admin,ghy567</xsl:text>
      <xsl:value-of select="$linefeed"/>
      <xsl:text>"User id","FirstName","LastName","BusinessTitle","Country"</xsl:text>
      <xsl:value-of select="$linefeed"/>
      <!--  for each Employee section -->
      <xsl:for-each select="/wd:Report_Data/wd:Report_Entry">
      <xsl:if test="wd:Flag ='UPDATE' and wd:Position Type !=''">
      <xsl:text>"</xsl:text>
      <xsl:value-of select="wd:Userid"/>
      <xsl:text>","</xsl:text>
      <xsl:value-of select="wd:FirstName"/>
      <xsl:text>","</xsl:text>
      <xsl:value-of select="wd:LastName"/>
      <xsl:text>","</xsl:text>
      <xsl:value-of select="wd:BusinessTitle"/>
      <xsl:text>","</xsl:text>
      <xsl:value-of select="wd:Country"/>
      </xsl:if>
      </xsl:for-each>
      </File>
      </xsl:template>
      </xsl:stylesheet>

XSLT 3

     <?xml version="1.0" encoding="UTF-8"?>
     <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
     xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" 
     xmlns:xtt="urn:com.workday/xtt" xmlns:wd="urn:com.workday.report/Demo_Report" 
     xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" version="2.0">
     <xsl:output method="text"/>
     <xsl:variable name="linefeed" select="'&#xA;'"/>
     <xsl:template match="wd:Report_Data">
     <File>
      <xsl:text>user,terminate,abc@y.com,admin,ghy567</xsl:text>
      <xsl:value-of select="$linefeed"/>
      <xsl:text>"User id","FirstName","LastName","BusinessTitle","Country"</xsl:text>
      <xsl:value-of select="$linefeed"/>
      <!--  for each Employee section -->
      <xsl:for-each select="/wd:Report_Data/wd:Report_Entry">
      <xsl:if test="wd:Flag ='TERMINATE' and wd:Position Type !=''">
      <xsl:text>"</xsl:text>
      <xsl:value-of select="wd:Userid"/>
      <xsl:text>","</xsl:text>
      <xsl:value-of select="wd:FirstName"/>
      <xsl:text>","</xsl:text>
      <xsl:value-of select="wd:LastName"/>
      <xsl:text>","</xsl:text>
      <xsl:value-of select="wd:BusinessTitle"/>
      <xsl:text>","</xsl:text>
      <xsl:value-of select="wd:Country"/>
      </xsl:if>
      </xsl:for-each>
      </File>
      </xsl:template>
      </xsl:stylesheet>

输出文件 1

用户,添加,abc@y.com,admin,ghy567
用户 ID、名字、姓氏、公司名称、国家/地区
12345，杰克，琼斯，工程师，美国

输出文件 2

用户，更新，abc@y.com，管理员，ghy567
用户 ID、名字、姓氏、公司名称、国家/地区
890767,Mike,Balder,Jr.Engineer,美国

输出文件 3

用户,终止,abc@y.com,admin,ghy567
用户 ID、名字、姓氏、公司名称、国家/地区
543908,Bolton,James,Sr.Engineer,US

现在我有另一个要求，必须将所有三个文件中的所有合并数据生成第 4 个文件，如下所示。

用户,添加,abc@y.com,admin,ghy567
用户 ID、名字、姓氏、公司名称、国家/地区
12345，杰克，琼斯，工程师，美国

用户，更新，abc@y.com，管理员，ghy567
用户 ID、名字、姓氏、公司名称、国家/地区
890767,Mike,Balder,Jr.Engineer,美国

用户,终止,abc@y.com,admin,ghy567
用户 ID、名字、姓氏、公司名称、国家/地区
543908,Bolton,James,Sr.Engineer,US

那么有没有一种方法可以将三个 XSLT 合并到一个文件中？

【问题讨论】：

好吧，XSLT 3 有fn:transform，所以它会允许这样做，XQuery 3.1 也是如此。 XProc 当然也可以做到。如果您擅长任何命令 shell 或脚本语言，您也可以调用 XSLT 处理器并连接结果。
提供的“XML”文档和样式表都严重畸形，并在解析时产生错误。请提供好人！！！喜欢：<wd:BusinessTitle>Sr.Engineer</wd:businessTitle> 和 <xsl:if test="wd:Flag ='HIRE' and wd:Position Type !=''"> 无需占用很多人的时间，同时为他们提供损坏的代码

标签： xslt xslt-1.0 xslt-2.0

【解决方案1】：

使用 XSLT 3 或 XQuery 3.1，您可以使用 fn:transform 从 XPath 运行 XSLT，因此在 XQuery 3.1 中您可以使用例如

declare namespace output = "http://www.w3.org/2010/xslt-xquery-serialization";

declare option output:method 'text';
declare option output:item-separator '&#10;&#10;';

declare variable $sheet-uris as xs:string* external := ('sheet1.xsl', 'sheet2.xsl', 'sheet3.xsl');

declare variable $sheets as document-node()* external :=  $sheet-uris ! doc(.);

let $xml := .
return
  $sheets 
  ! 
  transform(
    map {
        'stylesheet-node' : .,
        'source-node' : $xml,
        'delivery-format' : 'serialized'
    }
  )?output

或在 XSLT 3 中

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="3.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="#all"
  expand-text="yes">

  <xsl:param name="sheet-uris" as="xs:string*" select="'sheet1.xsl', 'sheet2.xsl', 'sheet3.xsl'"/>

  <xsl:param name="$sheets" as="document-node()*" select="$sheet-uris ! doc(.)"/>

  <xsl:output method="text" item-separator="&#10;&#10;"/>

  <xsl:template match="/">
    <xsl:sequence
     select="
      $sheets 
      ! 
      transform(
        map {
            'stylesheet-node' : .,
            'source-node' : current(),
            'delivery-format' : 'serialized'
        }
      )?output"/>
  </xsl:template>
  
</xsl:stylesheet>

您可以在XProc 3 中执行此操作（目前在测试版中由Morgana XProc III 支持，记录在https://www.xml-project.com/files/doc/manual.html）：

<p:declare-step name="concat" xmlns:p="http://www.w3.org/ns/xproc" version="3.0"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-inline-prefixes="#all">
    <p:input port="source"/>
    <p:option name="sheet-uris" as="xs:string*" select="'sheet1.xsl', 'sheet2.xsl', 'sheet3.xsl'"/>
    <p:output port="result" sequence="true" serialization="map { 'method' : 'text', 'item-separator' : '&#10;' }"/>
    <p:for-each>
        <p:with-input select="$sheet-uris"/>
        <p:xslt>
            <p:with-input port="source" pipe="source@concat"/>
            <p:with-input port="stylesheet" href="{.}"/>
        </p:xslt>
    </p:for-each>
</p:declare-step>

它使用 XProc https://spec.xproc.org/master/head/xproc/#p.for-each 的内置 p:for-each 步骤以及 p:xslt 步骤 https://spec.xproc.org/master/head/steps/#c.xslt 来针对作为 sheet-uris 选项提供的样式表序列运行输入源。

【讨论】：

马丁，谢谢..这看起来有点棘手，但让我试试吧。
@James，这些建议对你有用吗？
没有马丁，看起来我和下面一个很接近，但因为它没有 ETV/XTT 步骤..它不工作。

【解决方案2】：

怎么样：

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:wd="urn:com.workday.report/Demo_Report">
<xsl:output method="text"/>

<xsl:variable name="header2" select="'User id,FirstName,LastName,BusinessTitle,Country&#xA;'"/>

<xsl:template match="/wd:Report_Data">
    <!--  ADD -->
    <xsl:text>user,add,abc@y.com,admin,ghy567&#xA;</xsl:text>
    <xsl:value-of select="$header2"/>
    <xsl:apply-templates select="wd:Report_Entry[wd:Flag='HIRE']"/>
    <xsl:text>&#xA;</xsl:text>
    <!--  UPDATE -->
    <xsl:text>user,update,abc@y.com,admin,ghy567&#xA;</xsl:text>
    <xsl:value-of select="$header2"/>
    <xsl:apply-templates select="wd:Report_Entry[wd:Flag='UPDATE']"/>
    <xsl:text>&#xA;</xsl:text>
    <!--  TERMINATE -->
    <xsl:text>user,terminate,abc@y.com,admin,ghy567&#xA;</xsl:text>
    <xsl:value-of select="$header2"/>
    <xsl:apply-templates select="wd:Report_Entry[wd:Flag='TERMINATE']"/>
</xsl:template>
    
<xsl:template match="wd:Report_Entry">
    <xsl:text>"</xsl:text>
    <xsl:value-of select="wd:Userid"/>
    <xsl:text>","</xsl:text>
    <xsl:value-of select="wd:FirstName"/>
    <xsl:text>","</xsl:text>
    <xsl:value-of select="wd:LastName"/>
    <xsl:text>","</xsl:text>
    <xsl:value-of select="wd:BusinessTitle"/>
    <xsl:text>","</xsl:text>
    <xsl:value-of select="wd:Country"/>
    <xsl:text>"&#xA;</xsl:text>
</xsl:template>

</xsl:stylesheet>

【讨论】：

michael，谢谢，但是如果每个类别的数据字段不同怎么办？例如在更新数据中，如果我不希望填充国家数据值和终止数据，如果只填充用户 ID？
您可以使用与wd:Report_Entry 匹配的不同模板 - 每个模板都有自己的mode。
michael，我使用了不同的模板匹配 wd:Report_Entry 和它自己的数据字段。但是它返回所有其他模板的最后一个模板数据。例如 - 对于第三个模板匹配，如果我只给用户 ID 返回，第一个和第二个模板也只返回用户 ID，尽管它在模板中有其他数据字段。有什么想法吗？
为了避免这种情况，我在需要的地方使用了“if”条件。
@James 你明白“每个都有自己的mode”吗？ w3.org/TR/1999/REC-xslt-19991116/#modes