XSLT 在 for-each 中引用模板的当前节点

Question

如何在for-each 循环中引用模板匹配的当前节点。

<xsl:template match="product[@category='foo']">
    <count>
        <xsl:for-each select="preceding::product">
                <current>
                    <xsl:value-of select="count(current()/preceding::product)"/>
                </current>
                <context>
                    <xsl:value-of select="count(./preceding::product)"/>
                </context>
        </xsl:for-each>
    </count>
</xsl:template>

count() 和 . 和 current() 函数返回的结果相同。

有没有办法引用模板的匹配节点，以便计算它的所有前面的节点，以便<current/>内部的count()函数的结果对于每个for-each都是相同的一步。

谢谢！

Answer 1

将当前节点放入一个变量中......

<xsl:template match="product[@category='foo']">
    <xsl:variable name="current" select="." />
    <count>
        <xsl:for-each select="preceding::product">
                <current>
                    <xsl:value-of select="count($current/preceding::product)"/>
                </current>
                <context>
                    <xsl:value-of select="count(./preceding::product)"/>
                </context>
        </xsl:for-each>
    </count>
</xsl:template>

不过，在这个例子中，你最好将计数结果放在一个变量中......

将当前节点放入一个变量中......

<xsl:template match="product[@category='foo']">
    <xsl:variable name="count" select="count(preceding::product)" />
    <count>
        <xsl:for-each select="preceding::product">
                <current>
                    <xsl:value-of select="$count"/>
                </current>
                <context>
                    <xsl:value-of select="count(./preceding::product)"/>
                </context>
        </xsl:for-each>
    </count>
</xsl:template>