我想在不同级别执行两个元素的乘积之和答案

【问题标题】：I want perform sum of product of two elements at differnt levels我想在不同级别执行两个元素的乘积之和
【发布时间】：2013-01-22 22:28:12
【问题描述】：

我尝试了以下代码，但它不起作用。我取了一个字符串并在其中写入 XSLT 并加载它 XslCompiledTransform 对象。

 <xsl:sequence select=
        "sum(//Item/(cost * related_id/Item/quantity))"/>

源 XML：

<AML>
  <Item>
    <cost>
      40
    </cost>
    <related_id>
      <Item>
        <quantity>2</quantity>
      </Item>
    </related_id>
  </Item>
  <Item>
    <cost>
      50
    </cost>
    <related_id>
      <Item>
        <quantity>10</quantity>
      </Item>
    </related_id>
  </Item>
</AML>

【问题讨论】：

xsl:sequence 是 XSLT 2.0 的功能，而 XslCompiledTransform 仅支持 XSLT 1.0。您的源 XML 是什么样的？
我的源 XML 看起来像：<AML> <Item><cost>40<cost><related_id> <Item><quantity>2</quantity></Item> </related_id></Item> <Item><cost>50<cost><related_id> <Item><quantity>10</quantity></Item> </related_id></Item> </AML>
那我该怎么办？

标签： c# xml xslt xpath xslt-1.0

【解决方案1】：

正如我在 cmets 中所说，xsl:sequence 和您尝试使用的 XPath 语法在 XSLT 1.0（XslCompiledTransform 使用）中不可用，但您可以通过使用递归模板来获得公式的总和：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" indent="yes"/>

  <xsl:template match="/">
    <xsl:call-template name="SumSet">
      <xsl:with-param name="items" select="/*/Item" />
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="SumSet">
    <xsl:param name="items" />

    <xsl:if test="$items">
      <xsl:variable name="currentValue">
        <xsl:apply-templates select="$items[1]" />
      </xsl:variable>
      <xsl:variable name="remainderSum">
        <xsl:call-template name="SumSet">
          <xsl:with-param name="items" select="$items[position() > 1]" />
        </xsl:call-template>
      </xsl:variable>

      <xsl:value-of select="$currentValue + $remainderSum"/>
    </xsl:if>
    <xsl:if test="not($items)">0</xsl:if>
  </xsl:template>

  <xsl:template match="Item">
    <xsl:value-of select="cost * related_id/Item/quantity"/>
  </xsl:template>
</xsl:stylesheet>

在您的输入 XML 上运行时，结果是：

这将是通用方法，但由于您提到您正在使用 XslCompiledTransform，您可以使用 msxsl:node-set() 来稍微简化此任务：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt">
  <xsl:output method="text" indent="yes"/>

  <xsl:template match="/">
    <xsl:variable name="values">
      <xsl:apply-templates select="/*/Item" />
    </xsl:variable>

    <xsl:value-of select="sum(msxsl:node-set($values)/*)"/>
  </xsl:template>

  <xsl:template match="Item">
    <itemValue>
      <xsl:value-of select="cost * related_id/Item/quantity"/>
    </itemValue>
  </xsl:template>
</xsl:stylesheet>

当在您的输入 XML 上运行时，这也会产生值 580。

【讨论】：