【问题标题】:Performing a "Group By" query in XPath XSL在 XPath XSL 中执行“分组依据”查询
【发布时间】:2010-12-28 02:19:37
【问题描述】:

给定以下 XML:

<results name="queryResults">
  <int name="intfield1:[* TO 10]">11</int> 
  <int name="intfield2:[10 TO 20]">9</int> 
  <int name="intfield1:[10 TO 20]">12</int> 
</results>

我想生成这个 XML:

<results>
    <field name="numberfield1">
        <value name="[* TO 10]">11</value>
        <value name="[10 TO 10]">12</value>
    </field>
    <field name="numberfield2">
        <value name="[10 TO 20]">9</value>
    </field>
</results>

我想不出如何在 XSL 中执行此操作,主要是因为我想按数字字段分组.. 我能想到的是:

<xsl:if test="count(results/int) &gt; 0">
    <results>
    <xsl:for-each select="results/int">
        <field>
            <xsl:attribute name="name">
                <xsl:value-of select="substring-before(@name, ':')"/></xsl:attribute>
            <value>
                <xsl:attribute name="name">
                    <xsl:value-of select="substring-after(@name, ':') "/>
                </xsl:attribute>
                <xsl:value-of select="."/>
            </value>
        </field>
    </xsl:for-each>
    </results>
</xsl:if>

但是这并没有产生漂亮的分组列表,而是我得到了这个:

<results>
    <field name="numberfield1">
        <value name="[* TO 10]">11</value>
    </field>
    <field name="numberfield2">
        <value name="[10 TO 20]">9</value>
    </field>
    <field name="numberfield1">
        <value name="[10 TO 10]">12</value>
    </field>
</results>

如果有人能引导我朝着正确的方向前进.. 那会很棒吗?

谢谢

【问题讨论】:

    标签: xml xslt xpath xslt-1.0


    【解决方案1】:

    要在 XSLT 1.0 中执行此操作,您必须使用一种称为 "muenchian grouping" 的技术。首先创建要分组的节点的键

    <xsl:key name="intfield" match="int" use="substring-before(@name, ':')" />
    

    接下来,您遍历所有节点,但只选择恰好在相关组中排在第一位的节点

    <xsl:for-each select="int[generate-id() = generate-id(key('intfield', substring-before(@name, ':'))[1])]">
    

    接下来,你可以使用key来迭代组中的所有节点

    <xsl:variable name="intfieldname" select="substring-before(@name, ':')"/>
    <xsl:for-each select="key('intfield', $intfieldname)">
    

    把这一切放在一起给出了

    <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
       <xsl:output method="xml"/>
       <xsl:key name="intfield" match="int" use="substring-before(@name, ':')"/>
       <xsl:template match="/results">
          <results>
             <xsl:for-each select="int[generate-id() = generate-id(key('intfield', substring-before(@name, ':'))[1])]">
                <xsl:variable name="intfieldname" select="substring-before(@name, ':')"/>
                <field>
                   <xsl:attribute name="name">
                      <xsl:value-of select="$intfieldname"/>
                   </xsl:attribute>
                   <xsl:for-each select="key('intfield', $intfieldname)">
                      <value>
                         <xsl:attribute name="name">
                            <xsl:value-of select="substring-after(@name, ':')"/>
                         </xsl:attribute>
                         <xsl:value-of select="."/>
                      </value>
                   </xsl:for-each>
                </field>
             </xsl:for-each>
          </results>
       </xsl:template>
    </xsl:stylesheet>
    

    在你的例子中,'intfield' 变成了 'numberfield'。在上面的示例中,我将名称保留为“intfield”。

    • 修正了错字。

    【讨论】:

    • 你这个人.. 干杯.. 刚试了一下,效果很好。我得查一下这个“meunchian grouping”的事情,因为目前这一切看起来像是巫术
    • 一个问题...有没有办法限制它创建的 int 字段.. 因为还有另一个 int 列表在哪里,它把它们带入 intfield 键?希望这是有道理的
    • 是的,在 xsl:key 的 'match' 属性中,您可以输入任何完整的 Xpath 表达式,以更准确地了解您需要哪些节点。例如
    • 酷香蕉.. 谢谢.. 全部重新排序.. 就像一个魅力.. 我的用户会很高兴..
    【解决方案2】:

    Muenchian 分组是天才的杰作。这并不容易理解,但请参阅: http://www.jenitennison.com/xslt/grouping/muenchian.html

    为了简化流程,W3C 特别支持 XSLT2.0 中的分组。参见,例如: http://www.xml.com/pub/a/2003/11/05/tr.html

    但并非所有环境都支持 XSLT2.0

    【讨论】:

    • 使用 MS .NET 所以对我来说只有 XSL 1.0.. 不过你是对的.. 这是天才的作品.. 我会阅读该链接。谢谢
    猜你喜欢
    • 2018-05-25
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 2016-06-07
    • 2015-12-19
    • 1970-01-01
    • 1970-01-01
    相关资源
    最近更新 更多