【问题标题】:Issue with XML::Bare perlXML::Bare perl 的问题
【发布时间】:2014-08-10 04:33:44
【问题描述】:

我在 perl 中使用XML::Bare 模块。

我的 xml 是这样的:

<xml>
    <element num="1">
        <num>10</num>
    </element>
    <element num="2">
        <num>20</num>
    </element>
</xml>

我想提取子 &lt;num&gt; 标记中包含的值。即我想要10 and 20 作为输出。但是当我使用$xml-&gt;{element}-&gt;[$i]-&gt;{num}-&gt;{value} 获取值时,它返回1 adn 2,即它返回num 属性而不是子节点的值。 任何人都可以帮助我如何处理属性和子名称相同的情况。

谢谢

【问题讨论】:

  • XML::Simple 和 XML::Bare 使用的数据结构不能处理具有同名属性和子元素的元素,因为$ele-&gt;{num} 表示“属性或名为@987654329 的子元素@"。

标签: xml perl parsing


【解决方案1】:

如果使用XML::Bare 或XML::Simple,它们应该仅限于最基本的XML 读取。鉴于您的数据具有共享名称的属性和子节点,因此该限制不成立。

事实上,除非有特定的理由,否则应该坚持使用更现代的 XML 解析器,例如 XML::Twig 和 XML::LibXML 以及 XPath 支持的全部功能。

以下使用这两个模块解析您的 XML:

use strict;
use warnings;

use XML::LibXML;
use XML::Twig;

my $data = do {local $/; <DATA>};

print "XML::LibXML\n";
my $xml = XML::LibXML->load_xml(string => $data);
for my $node ($xml->findnodes('//element/num')) {
    print $node->textContent(), "\n";
}

print "XML::Twig\n";
my $t = XML::Twig->new( 
    twig_handlers => {
        '//element/num' => sub { print $_->text(), "\n" },
    },
);
$t->parse( $data );

__DATA__
<xml>
    <element num="1">
        <num>10</num>
    </element>
    <element num="2">
        <num>20</num>
    </element>
</xml>

输出:

XML::LibXML
10
20
XML::Twig
10
20

【讨论】:

    【解决方案2】:

    它看起来像 XML::Bare 中的一个错误。我在Dumper 输出中看不到&lt;num&gt; 元素:

    use warnings;
    use strict;
    use XML::Bare;
    
    my $xml = q(
    <xml>
        <element num="1">
            <num>10</num>
        </element>
        <element num="2">
            <num>20</num>
        </element>
    </xml>
    );
    
    my $ob = new XML::Bare( text => $xml );
    my $root = $ob->parse();
    
    use Data::Dumper;
    $Data::Dumper::Sortkeys=1;
    print Dumper($root);
    
    __END__
    
    $VAR1 = {
              '_i' => 0,
              '_pos' => 0,
              '_z' => 0,
              'value' => '
    ',
              'xml' => {
                         '_i' => 438404290,
                         '_pos' => 1,
                         '_z' => 130,
                         'element' => [
                                        {
                                          '_i' => 438404300,
                                          '_pos' => 2,
                                          '_z' => 64,
                                          'num' => {
                                                     '_att' => 1,
                                                     'value' => '1'
                                                   },
                                          'value' => '
            '
                                        },
                                        {
                                          '_i' => 438404359,
                                          '_pos' => 4,
                                          '_z' => 123,
                                          'num' => {
                                                     '_att' => 1,
                                                     'value' => '2'
                                                   },
                                          'value' => '
            '
                                        }
                                      ],
                         'value' => '
        '
                       }
            };
    

    You could submit a bug report.

    这是XML::Twig的解决方案:

    use warnings;
    use strict;
    use XML::Twig;
    
    my $xml = q(
    <xml>
        <element num="1">
            <num>10</num>
        </element>
        <element num="2">
            <num>20</num>
        </element>
    </xml>
    );
    
    my $twig= XML::Twig->new(twig_handlers => { element => \&elem });
    $twig->parse($xml);
    
    sub elem {
        my( $twig, $ele)= @_;
        my $att = $ele->att('num');
        my $num = $ele->first_child('num')->text();
        print "$att $num\n";
    }
    
    __END__
    
    1 10
    2 20
    

    【讨论】:

    • 谢谢,我也在考虑同样的事情...... :)
    猜你喜欢
    • 1970-01-01
    • 2011-10-11
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 2012-02-11
    • 2012-09-27
    • 1970-01-01
    相关资源
    最近更新 更多