FSharp.Data——如何处理空 JSON 值？

Question

我正在尝试将 FSharp.Data 示例转换为我正在处理的问题的解决方案，但我并没有走得太远。

问题

给定一个返回 json 的端点，类似于：

{
  Products:[{
    Id:43,
    Name:"hi"
  },
  {
    Id:45,
    Name:"other prod"
  }
  ]
}

如何加载数据，然后只从真实的现有数据中获取Ids？

我不明白如何“模式匹配”以下可能性：

• 它不会返回任何东西
• root.Products 可能不存在/为空
• Id 可能不存在

尝试通过空匹配

namespace Printio

open System 
open FSharp.Data
open FSharp.Data.JsonExtensions

module PrintioApi =
    type ApiProducts = JsonProvider<"https://api.print.io/api/v/1/source/widget/products?recipeId=f255af6f-9614-4fe2-aa8b-1b77b936d9d6&countryCode=US">

let getProductIds url =
    async {
        let! json = ApiProducts.AsyncLoad url
        let ids = match json with
            | null  -> [||]
            | _ -> 
                match json.Products with
                    | null -> [||]
                    | _ -> Array.map (fun (x:ApiProducts.Product)-> x.Id) json.Products

        return ids
        }

Answer 1

如果您对源数据有一定程度的信心，您可能不需要模式匹配来检查它是否为空数组。像这样的东西可能会很好用：-

let getProductIds url =
    async {
        let! json = ApiProducts.AsyncLoad url
        return json.Products |> Seq.map(fun p -> p.Id) |> Seq.cache
    }

注意你不应该在 async { } 块中使用 Async.RunSynchronously - 你可以做一个让！将异步等待结果的绑定。

Answer 2

编辑：当我写这个答案时，我并没有完全理解 JSON 类型提供程序的功能。事实证明，您可以使用示例 JSON 文档列表填充它，这使您能够处理可能存在或不存在数据的各种场景。这些天我经常使用它，所以我不再相信我最初写的东西。我将在此处保留原始答案，以防任何人从中获得任何价值。

请参阅我的other answer here on the page，了解我今天的做法。

---

虽然类型提供程序很好，但我认为尝试将像 JSON 这样没有架构和类型安全性的东西视为强类型数据在概念上是错误的。我没有使用类型提供程序，而是使用HttpClient、Json.NET 和FSharp.Interop.Dynamic 来编写如下查询：

let response = client.GetAsync("").Result
let json = response.Content.ReadAsJsonAsync().Result
let links = json?links :> obj seq
let address =
    links
    |> Seq.filter (fun l -> l?rel <> null && l?href <> null)
    |> Seq.filter (fun l -> l?rel.ToString() = rel)
    |> Seq.map (fun l -> Uri(l?href.ToString()))
    |> Seq.exactlyOne

其中client 是HttpClient 的一个实例，ReadAsJsonAsync 是一个小助手方法，定义如下：

type HttpContent with
    member this.ReadAsJsonAsync() =
        let readJson (t : Task<string>) =
            JsonConvert.DeserializeObject t.Result
        this.ReadAsStringAsync().ContinueWith(fun t -> readJson t)

Answer 3

给类型提供者足够的例子来推断这些情况。示例：

[<Literal>]
let sample = """
{
  Products:[{
    Id:null,
    Name:"hi"
  },
  {
    Id:45,
    Name:"other prod"
  }
  ]
}
"""

type MyJsonType = JsonProvider<sample>

但请注意，如果 json 不够规则，它永远不会 100% 安全

Answer 4

如果您怀疑您的数据源可能包含一些缺失值，您可以在 JsonProvider 中设置SampleIsList = true，并给它一个示例列表，而不是单个示例：

open FSharp.Data

type ApiProducts = JsonProvider<"""
[
    {
        "Products": [{
            "Id": 43,
            "Name": "hi"
        }, {
            "Name": "other prod"
        }]
    },
    {}
]
""", SampleIsList = true>

正如 Gustavo Guerra 在他的回答中暗示的那样，Products 已经是一个列表，因此您可以提供一个具有 Id（第一个）的产品示例，以及一个没有Id（第二个）。

同样，您可以举一个完全没有Products 的例子。由于根对象不包含其他数据，因此这只是一个空对象：{}。

JsonProvider 足够智能，可以将缺少的 Products 属性解释为空数组。

由于产品可能有也可能没有Id，因此推断此属性的类型为int option。

您现在可以编写一个函数，该函数将 JSON 字符串作为输入，并为您提供它可以找到的所有 ID：

let getProductIds json =
    let root = ApiProducts.Parse json
    root.Products |> Array.choose (fun p -> p.Id)

请注意，它使用Array.choose 而不是Array.map，因为Array.choose 会自动选择那些Id 值Some。

您现在可以使用各种值进行测试以查看其是否有效：

> getProductIds """{ "Products": [{ "Id": 43, "Name": "hi" }, { "Id": 45, "Name": "other prod"  }] }""";;
> val it : int [] = [|43; 45|]

> getProductIds """{ "Products": [{ "Id": 43, "Name": "hi" }, { "Name": "other prod" }] }""";;
> val it : int [] = [|43|]

> getProductIds "{}";;
> val it : int [] = [||]

但是，它仍然会在空输入时崩溃；如果 JsonProvider 有 TryParse 函数或类似函数，我还没有找到...