在Perl6中逐行读取文件，如何惯用？

Question

我在 Perl6 中有一个基本脚本，它运行非常很慢，比精确的 perl5 翻译慢大约 30 倍。

CONTROL {
    when CX::Warn {
        note $_;
        exit 1;
    }
}
use fatal;
role KeyRequired {
    method AT-KEY (\key) {
        die "Key {key} not found" unless self.EXISTS-KEY(key);
        nextsame;
    }
}

for dir(test => /^nucleotide_\d**2_\d**2..3\.tsv$/) -> $tsv {
    say $tsv;
    my $qqman = $tsv.subst(/\.tsv$/, '.qqman.tsv');
    my $out = open $qqman, :w;
    put "\t$qqman";
    my UInt $line-no = 0;
    for $tsv.lines -> $line {
        if $line-no == 0 {
            $line-no = 1;
            $out.put(['SNP', 'CHR', 'BP', 'P', 'zscore'].join("\t"));
            next
        }
        if $line ~~ /.+X/ {
            next
        }
        $line-no++;
        my @line = $line.split(/\s+/);
        my $chr = @line[0];
        my $nuc = @line[1];
        my $p = @line[3];
        my $zscore = @line[2];
        my $snp = "'rs$line-no'";
        $out.put([$snp, $chr, $nuc, $p, $zscore].join("\t"));
        #$out.put();
    }
    last
}

这是 Perl5 的 while 的惯用语。

这是一个非常简单的脚本，它只改变文件中的文本列。这个 Perl6 脚本在 30 分钟内运行。 Perl5 翻译运行时间为 1 分钟。

我已尝试阅读 Using Perl6 to process a large text file, and it's Too Slow.(2014-09) 和 Perl6 : What is the best way for dealing with very big files?，但在这里我没有看到任何可以帮助我的东西 :(

我正在运行Rakudo version 2018.03 built on MoarVM version 2018.03 implementing Perl 6.c.

我意识到 Rakudo 还没有成熟到 Perl5 的水平（我希望如此），但是我怎样才能让它在更合理的时间范围内逐行读取文件？

Answer 1

我会改变很多事情。

• /.+X/ 可以简化为 /.X/ 甚至 $line.substr(1).contains('X')
• $line.split(/\s+/) 可以简化为 $line.words
• $tsv.subst(/\.tsv$/, '.qqman.tsv') 可以简化为 $tsv.substr(*-4) ~ '.qqman.tsv'
• uint 而不是 UInt
• given .head {} 而不是 for … {last}

given dir(test => /^nucleotide_\d**2_\d**2..3\.tsv$/).head -> $tsv {
    say $tsv;
    my $qqman = $tsv.substr(*-4) ~ '.qqman.tsv';
    my $out = open $qqman, :w;
    put "\t$qqman";

    my uint $line-no = 0;
    for $tsv.lines -> $line {
        FIRST {
            $line-no = 1;
            $out.put(('SNP', 'CHR', 'BP', 'P', 'zscore').join("\t"));
            next
        }
        next if $line.substr(1).contains('X');

        ++$line-no;

        my ($chr,$nuc,$zscore,$p) = $line.words;

        my $snp = "'rs$line-no'";
        $out.put(($snp, $chr, $nuc, $p, $zscore).join("\t"));
        #$out.put();
    }
}