Terraform - 迭代嵌套地图答案

【问题标题】：Terraform - iterate over nested mapTerraform - 迭代嵌套地图
【发布时间】：2020-12-09 12:33:53
【问题描述】：

我正在尝试使用资源 google_bigquery_dataset_iam_binding 为 Bigquery 数据集创建 IAM 绑定。要求是我使用以下结构的变量读取此资源中的参数（dataset_id、角色、成员）-

  bq_iam_role_bindings = {
    "member1" = {
      "dataset1" : ["role1","role2", "role5"],
      "dataset2" : ["role3","role2"],
    },
    "member2" = {
      "dataset3" : ["role1","role4"],
      "dataset2" : ["role5"],
    } 
  }

因此，我需要遍历此变量并获取在数据集上为每个成员分配的角色。此处创建的总资源为 8 个（对于每个成员、每个数据集和每个角色）。我是 terraform 的新手，只了解如何在地图上应用简单的 for 循环和在资源中应用 for_each 循环。想了解我想要做什么。

这是我找到的最接近的 -Map within a map in terraform variables，我可以在其中读取嵌套映射中的值，但在我的情况下我也需要提取键。谁能帮帮忙。

【问题讨论】：

这能回答你的问题吗？ Use a map of lists of maps in resource creation
您需要“手动”迭代地图，flatten 结果，然后在for_each 中使用该结果。
但是我将如何引用 for_each 中的 3 个参数——成员、数据集 ID 和角色
你最终会遍历一个映射，映射的键是所有这三个参数的唯一组合（例如“something|some_data|some_role”），而值将是结构映射{member="something" dataset_id="some_data" role="some_role"}

标签： terraform nested-loops terraform-provider-gcp nested-map

【解决方案1】：

您可以将其重新组织成更多 for_each 友好的对象列表，并将其存储在本地 helper_list 中。

例如：

variable "bq_iam_role_bindings" {

  default = {
    "member1" = {
      "dataset1" : ["role1","role2", "role5"],
      "dataset2" : ["role3","role2"],
    },
    "member2" = {
      "dataset3" : ["role1","role4"],
      "dataset2" : ["role5"],
    } 
  }
}

locals {

  helper_list = flatten([for member, value in var.bq_iam_role_bindings:
                 flatten([for dataset, roles in value: 
                           [for role in roles:
                            {"member" = member
                            "dataset" = dataset
                            "role" = role}
                         ]])
                   ])
}

这将导致helper_list 的形式为：

[
  {
    "dataset" = "dataset1"
    "member" = "member1"
    "role" = "role1"
  },
  {
    "dataset" = "dataset1"
    "member" = "member1"
    "role" = "role2"
  },
  {
    "dataset" = "dataset1"
    "member" = "member1"
    "role" = "role5"
  },
  {
    "dataset" = "dataset2"
    "member" = "member1"
    "role" = "role3"
  },
  {
    "dataset" = "dataset2"
    "member" = "member1"
    "role" = "role2"
  },
  {
    "dataset" = "dataset2"
    "member" = "member2"
    "role" = "role5"
  },
  {
    "dataset" = "dataset3"
    "member" = "member2"
    "role" = "role1"
  },
  {
    "dataset" = "dataset3"
    "member" = "member2"
    "role" = "role4"
  },
]

上面的表格使用for_each更容易，例如：

resource "google_bigquery_dataset_iam_binding" "reader" {

  for_each =  { for idx, record in local.helper_list : idx => record }

  dataset_id = each.value.dataset
  role       = each.value.role

  members = [
    each.value.member
  ]
}

【讨论】：

这让它变得如此简单。正是我试图得到它的方式......非常感谢！
因为这是一个列表而不是一个集合，但是如果任何“数据集”列表的顺序发生变化，terraform 会尝试销毁并重新创建所有元素，对吗？