用于“翻转”内部和外部 XML 的 XSLT 选项

Question

我正在评估 XSLT 操作（1.0 和 2.0）是否可以实现以下转换：

原始 XML：

<?xml version="1.0" encoding="UTF-8"?>
<testsuites>
   <testsuite name="suiteOne">
      <testcase name="testOne" />
      <testcase name="testTwo" />
      <testcase name="testThree" />
   </testsuite>
   <testsuite name="suiteTwo">
      <testcase name="testFour" />
      <testcase name="testOne">
         <failure message="it failed">Stuff happened oh no oh geez</failure>
      </testcase>
   </testsuite>
</testsuites>

转换后的xml：

<?xml version="1.0" encoding="UTF-8"?>
<testsuites>
   <testsuite name="testOne">
      <testcase name="suiteOne" />
      <testcase name="suiteTwo">
         <failure message="it failed">Stuff happened oh no oh geez</failure>
      </testcase>
   </testsuite>
   <testsuite name="testTwo">
      <testcase name="suiteOne" />
   </testsuite>
   <testsuite name="testThree">
      <testcase name="suiteOne" />
   </testsuite>
   <testsuite name="testFour">
      <testcase name="suiteTwo" />
   </testsuite>
</testsuites>

基本上，我需要在维护关系的同时“交换”内部和外部 xml。这在许多语言中是非常可行的，我可以遍历原始 xml 并跟踪我已经遇到的内容（通过字典或类似的东西），但是对于 XLST，我不确定它可能是多么微不足道或复杂.任何建议表示赞赏。

Answer 1

这似乎基本上是一个带有扭曲的分组问题。我认为这是您可以查看的一种方式：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/testsuites">
    <xsl:copy>
        <xsl:for-each-group select="testsuite/testcase" group-by="@name">
            <testsuite name="{@name}">
                <xsl:for-each select="current-group()">
                    <testcase name="{../@name}">
                        <xsl:copy-of select="*"/>
                    </testcase>
                </xsl:for-each> 
            </testsuite>
        </xsl:for-each-group>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

演示：https://xsltfiddle.liberty-development.net/pNEj9dz/2