释放 TObjectList 时访问冲突

Question

我有以下 Delphi 代码：

destructor TXX_XXXX.Destroy;
var
i: Integer;
begin
  if Assigned(Allocations) then
  begin
    for i:=0 to (Allocations.Count - 1) do 
    begin
      try
      TXX_ALOC(Allocations.Items[i]).Free;
      except on Ex:Exception do
      begin
        OutputDebugString(PChar('Exception Error Message '+ Ex.Message));
      end;
      end;
    end;

        // Above code works well - no exception

        try
    FreeAndNil(Allocations); {Exception Here}
    except on E:Exception do
    begin
      OutputDebugString(PChar('Exception in xxxxxxxxx.pas'+E.Message));
    end;
    end;
  end;
  inherited;
end;

模块“Vcl50.bpl”中地址 4003AB4 的访问冲突。读取地址 2980BFFC

我知道访问冲突通常是由

引起的

1. 释放一些之前被释放的对象
2. 使用一些没有初始化的对象

但在我做免费之前，我检查了分配已分配。如果我放弃异常处理，我的应用程序将抛出一些错误错误。 Allocations 是一个 TObjectList，如果它是一个数组 - 我会怀疑我没有为数组分配长度，但它是一个 TObjectList。

非常感谢！

Answer 1

TObjectList 通常会负责销毁其内容。在这种情况下不要释放你的对象。这会在释放 TObjectList 时导致访问冲突，因为它会再次尝试释放包含的对象。

对象列表的这种行为可以在其构造函数中控制：

constructor TObjectList.Create(AOwnsObjects: Boolean);

使用这个来指定您是否希望列表拥有它的内容（意味着：当它从列表中删除或列表被销毁时，它负责销毁项目）或不。没有参数的构造函数（您可能使用过）将其设置为true。

您可能只需要像TList 这样的列表，但用于存储对象。如果是这种情况，请像这样创建您的列表：

Allocations:= TObjectList.Create(False);

但是，如果您想要自动销毁行为，那么只需删除 for 循环。对象列表将销毁您的 TXX_ALOC 对象。

Answer 2

通常，在清除列表时，您希望从头到尾循环，即

for i := (Allocations.Count - 1) downto 0 do begin
   Delete(Allocations.Items[i]);
end

但在TObjectList 的情况下，如果列表拥有对象（默认情况下会这样做），您不应该在销毁容器之前释放它们，因为列表会为您执行此操作。在上面的代码中，如果列表拥有对象，那么调用 Delete 也会释放对象。

Answer 3

您有 2 个选项...

1) 如果您希望 Delphi 在将对象从 ObjectList 中删除时自动释放这些对象，请创建将 aOwnsObjects 设置为 true 的 TObjectList。在您的 Destructor 中，简单的 FreeAndNil 是 ObjectList 本身。这将从列表中删除所有对象并自动释放它们。由于释放 ObjectList 将自动释放该列表中包含的对象，因此您的代码可能如下所示：

destructor TXX_XXXX.Destroy;
begin
  FreeAndNil( Allocations ); //
  inherited;
end;

2) 创建 TObjectList 并将 aOwnsObjects 设置为 False，在这种情况下，您必须自己处理释放列表中的对象。你的代码可能看起来像这样：

destructor TXX_XXXX.Destroy;
var
  i       : Integer;
  oObject : TObject;
begin
  if Assigned(Allocations) then
  begin
    for i:= Pred( Allocations.Count ) downto 0 do
    begin
      // Get a reference to the Object
      oObject := TXX_ALOC(Allocations.Items[i]);
      // Remove the object from the object list
      Allocations.Delete( i );
      // Free the Object
      FreeAndNil( oObject );
    end;
  end;

  FreeAndNil( Allocations );
  inherited;
end;