如何初始化 var Record 参数

Question

我有记录类型：

type
  TIPInfo = record
    IP,
    HostName,
    City,
    Region,
    Country,
    Loc,
    Org: WideString
  end;

返回记录数据的函数：

function GetPublicIPInfo(var IPInfo: TIPInfo): Boolean;
begin
  // initialize
  FillChar(IPInfo, SizeOf(TIPInfo), 0);

  // populate data
  IPInfo.IP := GetVallue('ip');
  IPInfo.HostName := GetVallue('hostname');
  IPInfo.City := GetVallue('city');
  // etc...

  Result := IsOk;   
end;

调用者：

var
  IPInfo: TIPInfo;

if GetPublicIPInfo(IPInfo) then... // use data

通过调用FillChar 来初始化var TIPInfo 是正确的方法还是应该将每个字段都设置为空字符串？调用者应该这样做吗？

另外，在这种情况下使用out参数会更好吗（因为函数没有读取数据）？

Answer 1

这里只使用FillChar 是错误的。如果任何WideString 成员不为空，那么您将以这种方式泄漏它们。相反，我建议如下：

Finalize(IPInfo);
FillChar(IPInfo, SizeOf(TIPInfo), 0);

或者另一种方式是将默认记录定义为类型化常量：

const
  DefaultIPInfo: TIPInfo = ();

然后你可以使用简单的赋值：

IPInfo := DefaultIPInfo;

在现代版本的 Delphi 中，您可以改用以下更具可读性的代码：

IPInfo := Default(TIPInfo);

有关此特定主题的更多信息，请参阅以下主题：

• Delphi "default" keyword with Record types in older Delphi versions。
• How to properly free records that contain various types in Delphi at once?

请注意，您的代码中的泄漏很难找到，因为WideString 变量被实现为COM BSTR 对象，并分配在COM 堆上。因此，如果您对 Delphi 内存管理器使用内存泄漏检测，则不会检测到泄漏，因为它是从不同的堆中泄漏的。

在您的情况下，因为您的记录是托管类型，并且仅包含托管类型，所以您可以使用 out 参数来获得良好的效果。对于托管类型，out 参数意味着编译器将在调用站点生成代码，在传入之前默认初始化记录。

考虑以下程序：

{$APPTYPE CONSOLE}

type
  TRec = record
    Value: WideString;
  end;

procedure Foo1(var rec: TRec);
begin
end;

procedure Foo2(out rec: TRec);
begin
end;

procedure Main;
var
  rec: TRec;
begin
  rec.Value := 'Foo';
  Foo1(rec);
  Writeln(rec.Value);
  Foo2(rec);
  Writeln(rec.Value);
end;

begin
  Main;
end.

输出是：

富

如果您的记录包含托管和非托管类型的混合，那么情况就不太好了。

{$APPTYPE CONSOLE}

type
  TRec = record
    Value1: WideString;
    Value2: Integer;
  end;

procedure Foo1(var rec: TRec);
begin
end;

procedure Foo2(out rec: TRec);
begin
end;

procedure Main;
var
  rec: TRec;
begin
  rec.Value1 := 'Foo';
  rec.Value2 := 42;
  Foo1(rec);
  Writeln(rec.Value1);
  Writeln(rec.Value2);
  Foo2(rec);
  Writeln(rec.Value1);
  Writeln(rec.Value2);
end;

begin
  Main;
end.

输出是：

富 42 42

只有托管成员默认为out 参数初始化。所以最好的办法是默认自己初始化变量，即使它是作为out 参数传递的。

更多关于out参数可以在这里找到：What's the difference between "var" and "out" parameters?