搜索并移动目录中的所有文件，但将两个文件批量保存

【问题标题】：search and move all files in directory but keep both files in batch搜索并移动目录中的所有文件，但将两个文件批量保存
【发布时间】：2014-08-07 22:47:34
【问题描述】：

我想复制分配的（声音）文件，这些都是不同的声音，但大多数文件名都是相同的......并且文件位于以随机字符作为名称的子文件夹中。

但是如何搜索所有随机子文件夹中的所有声音文件并将其复制到一个文件夹中？但保留两个双文件，不要覆盖它们，例如：

而不仅仅是：Ambient.wav

对此：Ambient(1).wav Ambient(2).wav Ambient(3).wav 等...

我使用的是 Windows 7 Ultimate

【问题讨论】：

How to copy certain files (w/o folder hierarchy), but do not overwrite existing files? 的可能重复项我认为这几乎完全符合您的要求，除了可能有细微的变化（在接受的答案中，您可以添加一个变量并添加其数值，而不是仅复制第一个改为文件名）加上 xxcopy 正是这样做的）
但它不会从所有随机目录中复制声音文件

标签： windows file batch-file copy

【解决方案1】：

@ECHO OFF
SETLOCAL
SET "sourcedir=U:\sourcedir"
SET "destdir=U:\destdir"
FOR /f "delims=" %%a IN (
 'dir /s /b /a-d "%sourcedir%\*" '
 ) DO (
 IF EXIST "%destdir%\%%~nxa" (
  SET notfound=Y
  FOR /L %%b IN (1,1,999) DO IF DEFINED notfound IF NOT EXIST "%destdir%\%%~na(%%b)%%~xa" (
   ECHO(COPY "%%a" "%destdir%\%%~na(%%b)%%~xa"
   SET "notfound="
  )
  IF DEFINED notfound ECHO(Failed to COPY "%%a"
 ) ELSE (ECHO(COPY "%%a" "%destdir%\%%~nxa"
 )
)

GOTO :EOF

所需的 COPY 命令仅用于测试目的ECHOed。 验证命令正确后，将ECHO(COPY更改为COPY以实际复制文件。

当然，如果您愿意，copy 可以变为 move。

如果需要，您可以将 >nul 添加到 copy 以隐藏 copied 消息。

我对所有文件都使用了* 掩码。如果你只想说.jpgs，那就把"%sourcedir%\*"改成"%sourcedir%\*.jpg"

【讨论】：