批量混合特殊字符故障？

Question

据我所知，一些特殊字符如果使用“”回显它们是可以显示的。我只是停留在代码上，试图弄清楚我可以在哪里更改以使其正常工作。我看不出问题。来自here 的代码。 我需要的是一个可以为我编写动画然后退出的特殊代码。就这样。我从there 复制了代码，修改后可以使用typewriter.bat "text" "charsnum-1" 调用它，例如typewriter "Hello" 4。虽然我真正不了解 Batch Hybrids，而且即使知道如何解释代码，我也看不出符号卡在哪里。

重现我的问题：typewriter.bat "Hello?" 5

代码：

@if (@CodeSection == @Batch) @then

@echo off
setlocal

color 70
set charnuu=%2

call :split chars %1

:begin
for %%i in (%chars%) do call :type "%%~i"
exit /b
goto begin

:split <var_to_set> <str>
setlocal enabledelayedexpansion
set "line="
set "str=%~2"
for /L %%I in (0,1,%charnuu%) do set line=!line! "!str:~%%I,1!"
endlocal & set "%~1=%line%"
goto :EOF

:type <char>
cscript /nologo /e:JScript "%~f0" "%~1"
goto :EOF

@end
// end batch / begin JScript chimera
function pause() { WSH.Sleep(Math.random() * 50 + 50); }
function odds(num) { return !(Math.round(Math.random() * num) % num) }


pause();

if (odds(300)) WSH.Echo('');
if (!odds(400)) WSH.StdOut.Write(WSH.Arguments(0));

此代码没有显示常见符号，甚至没有显示基本符号，例如 ?。也许我太累了，看不到它。帮帮我。

Answer 1

常规的for 循环无法处理问号，但您可以通过完全不使用循环处理单个字母而仅将整个字符串作为一个整体进行迭代来解决这个问题：

@echo off

REM Just kinda honor-system the string length since this is proof of concept
REM     but remember that string indices start at 0
set "string=%~1"
set "string_length=%~2"

REM Generate a backspace character for later
for /f %%A in ('"prompt $H&for %%B in (1) do rem"') do set "BS=%%A"

REM The setlocal is down here instead of at the top like it usually is to handle
REM     strings that contain exclamation points.
REM There's a period followed by a backspace before the substring is printed in
REM     case the current character happens to be a space (which otherwise
REM     wouldn't get printed).
REM The timeout /t 0 is because timeout is an external command that technically
REM     needs a few milliseconds to start up, so setting the wait period to 0
REM     seconds actually generates a pause shorter than 1 second.
setlocal enabledelayedexpansion
for /L %%A in (0,1,%string_length%) do (
    <nul set /p "=.%BS%!string:~%%A,1!"
    >nul timeout /t 0
)