Telerik，如何在 RadForm TitleBar 中正确添加 RadButtonElement？

Question

我正在尝试在标题栏中添加一个按钮，我想赋予它与其他按钮相同的外观，但我无法做到，请参阅：

请注意，我的新按钮颜色比其他按钮更亮，而且尺寸突出了黄色边框。

这是我正在使用的代码：

Imports Telerik.WinControls.UI

Public Class RadForm_TestForm : Inherits RadForm

Public Sub New()

    ' This call is required by the designer.
    InitializeComponent()

    ' Set the RadForm design.
    With Me

        .ThemeName = "VisualStudio2012Dark" ' The visual theme.
        .FormElement.Border.ForeColor = Color.Gold   ' Set the borders color.
        .FormElement.Border.Width = 1I ' Set the borders width.
        .FormElement.TitleBar.BorderPrimitive.ForeColor = Color.Red
        .FormElement.TitleBar.ForeColor = Color.LightGray ' Set the TitleBar text color.
        .FormElement.TitleBar.MinimizeButton.Enabled = False

    End With

    ' Create a RadButtonElement.
    Dim SystrayButton As New RadButtonElement()
    With SystrayButton ' Set the RadForm design.

        .Text = "."
        .ShowBorder = False
        .AutoSize = False

        .Size = Me.FormElement.TitleBar.MinimizeButton.Size
        '  .ButtonFillElement.BackColor = Me.FormElement.TitleBar.MinimizeButton.BackColor

    End With

    ' Add the Button in the TitleBar.
    Me.FormElement.TitleBar.Children(2).Children(0).Children.Insert(0, SystrayButton)

End Sub

End Class

请注意，在上面的代码中，这一行被禁用：

.ButtonFillElement.BackColor = Me.FormElement.TitleBar.MinimizeButton.BackColor

因为如果我以这种方式更改颜色，如果我将鼠标放在按钮上，它在聚焦时不会改变颜色。

更新：

也许解决方案可以在RadButtonElement 上应用我的RadForm 的相同主题？

我读过这个：http://www.telerik.com/forums/apply-theme-to-radbuttonelement

...但我真的不明白该怎么做，我没有任何“DefaultStyleBuilder”，我在 Telerik 中找不到关于这意味着什么的信息。

Answer 1

+1 我看到了难题。

如果您想在标题栏中显示按钮的悬停、按下和正常状态，您需要创建三个图像并将它们应用于鼠标事件，即在 MouseEnter 上应用悬停图像，在 MouseLeave 上应用正常图像和在 MouseDown 上按下图像。

我看到按钮与黄线略微重叠，因此您可能需要使用图像来解决这个问题。

像你说的那样设置 RadButton BackColors 将阻止默认的悬停、按下和正常状态行为。

看起来您做得正确 - 一个细微的变化是使用 TitleBar.SystemButtons 而不是遍历继承的 TitleBar.Children(2).Children(0).Children.

您可以这样做：

RadButtonElement btn = new RadButtonElement();
btn.ShowBorder = false;
btn.Image = Resources.NormalState;
this.FormElement.TitleBar.SystemButtons.Children.Insert(0,btn);

ps 我不认为使用“StyleBuilders”可以让你获得你想要的外观，顺便说一句，这个请求已被建议给 Telerik：http://feedback.telerik.com/Project/154/Feedback/Details/109772-add-helpbutton-at-the-titlebar-of-radform

Answer 2

Telerik 论坛管理员建议的解决方案：

FormElement.TitleBar.SystemButtons 集合包含 RadImageButtonElements。为了向标题栏添加新的系统按钮，您应该创建一个 RadImageButtonElement。此外，要获得与最小化按钮相同的设计，您应该将 RadImageButtonElement.ThemeRole 属性设置为“TitleBarMinimizeButton”。然后，将 DisplayStyle 属性更改为 Text。这是一个示例代码sn-p：

Sub New()
    InitializeComponent()

    With Me
        .ThemeName = "VisualStudio2012Dark" ' The visual theme.
        .FormElement.Border.ForeColor = Color.Gold ' Set the borders color.
        .FormElement.Border.Width = 1I ' Set the borders width.
        .FormElement.TitleBar.BorderPrimitive.ForeColor = Color.Red
        .FormElement.TitleBar.ForeColor = Color.LightGray ' Set the TitleBar text color.
        .FormElement.TitleBar.MinimizeButton.Enabled = False
    End With

    ' Create a RadButtonElement.
    Dim systrayButton As New RadImageButtonElement()
    With systrayButton ' Set the RadForm design.
        .ThemeRole = "TitleBarMinimizeButton"
        .Text = "."
        .DisplayStyle = Telerik.WinControls.DisplayStyle.Text
        .ShowBorder = False
        .AutoSize = False
        .Size = Me.FormElement.TitleBar.MinimizeButton.Size
    End With
    AddHandler systrayButton.Click, AddressOf systrayButton_Click
    ' Add the Button in the TitleBar.
    Me.FormElement.TitleBar.SystemButtons.Children.Insert(0, systrayButton)
End Sub

Private Sub systrayButton_Click(sender As Object, e As EventArgs)
    Me.Size = New Size(600, 600)
End Sub

来源：http://www.telerik.com/forums/how-to-properly-add-a-radbuttonelement-in-a-radform-titlebar