编写一个读取用户名的简单引导加载程序

Question

我正在尝试了解操作系统的工作原理。这是一个我很难解决的简单任务：编写一个简单的引导加载程序，提示用户输入他的名字并打印欢迎消息，如“你好，>>name

如果有任何相关性，我正在运行 minix 3 和 qemu。我只是将asm 文件和dd 的前512 个字节编译为/dev/c0d0（minix 的虚拟硬盘驱动器）。

我可以打印消息并打印用户输入的内容。但是，后来我没能打印出用户名。

这是我的汇编代码：

[bits 16]
[org 0x7c00]

mov si, HelloString
call print_string
mov di, name
call read_name
mov si, name
call print_string

read_name:
    read_char:
        mov ah, 0h  ; read character from keyboard
        mov [di], ah    ; save it in the buffer
        inc di      ; next char
        int 0x16    ; store it in AL
        cmp ah, 0x0d    ; check for enter
        je stop_reading 
        mov ah, 0eh     ; display character in AL
        int 0x10    ; echo it
        jmp read_char   ; an so on
    stop_reading:
        mov si, EoL
        call print_string
        ret

print_char:
    mov ah, 0x0e    ; one char
    mov bh, 0x00    ; page number
    mov bl, 0x07    ; font color
    int 0x10
    ret

print_string:
    next_char:
        mov al, [si]
        inc si
        or al, al
        jz exit_function
        call print_char
        jmp next_char
    exit_function:
        ret

;data
HelloString db 'Enter your name', 0xd, 0xa, 0
name times 20 db 0
EoL db 0xd, 0xa, 0

times 510 - ($ - $$) db 0;
dw 0xaa55

我做错了什么？

Answer 1

您的代码存在许多问题。罗斯和我在 cmets 中指出了一些。你应该阅读我的General Bootloader Tips。尽管与您的实际问题无关，但您应该将 DS （如果最终需要，也可以将 ES 设置为 0，因为您使用的原点为 0x7c00 (org 0x7c00) .您还应该在您知道代码不会破坏的地方设置堆栈。我之前会将此代码添加到顶部：

    mov si, HelloString
    call print_string

改为：

    xor ax, ax         ; AX=0
    mov ds, ax
    mov es, ax
    mov ss, ax         ; SS=ES=DS=0
    mov sp, 0x7c00     ; Place stack before the bootloader. Grows down from 0x0000:0x7c00

    mov si, HelloString
    call print_string

在您的代码完成运行后，您应该将 CPU 置于一个无限循环中，这样它就不会通过在主代码下方执行您的函数来继续。所以在标签read_name: 之前放置一个无限循环。这样的事情很典型：

    cli                ; Turn off interrupts        
endloop:
    hlt                ; Halt processor until next interrupt encountered
    jmp endloop        ; Jump back just in case we get an MNI (non-maskable interrupt)

您的read_char 函数中有一些错误。 BIOS 中断信息的最佳位置之一是Ralph Brown's Interrupt List。 Int 0x16/AH=0 记录为：

AH = 00h

Return:
AH = BIOS scan code
AL = ASCII character

您应该使用 AL 中的 ASCII 字符来存储到您的字符串缓冲区。您还应该将 AL 与 0x0d 进行比较，而不是 AH（这是键盘扫描代码，而不是 ASCII 字符）。在使用int 0x16 读取字符之前，您还将数据存储到字符串缓冲区中。之后您需要将它们放入缓冲区中。当您到达stop_reading: 时，您需要在缓冲区末尾放置一个 NUL (0x00) 字符。

read_name 的代码可能如下所示：

read_name:
read_char:
    mov ah, 0h  ; read character from keyboard
    int 0x16    ; store it in AL
    cmp al, 0x0d    ; check for enter
    je stop_reading
    mov [di], al    ; save it in the buffer
    inc di      ; next char
    mov ah, 0eh     ; display character in AL
    int 0x10    ; echo it
    jmp read_char   ; an so on
stop_reading:
    mov byte [di], 0x00    ; NUL terminate buffer
    mov si, EoL
    call print_string
    ret

修改后的引导加载程序可能如下所示：

[bits 16]
[org 0x7c00]

    xor ax, ax         ; AX=0
    mov ds, ax
    mov es, ax
    mov ss, ax
    mov sp, 0x7c00     ; Place stack before the bootloader. Grows down from 0x0000:0x7c00

    mov si, HelloString
    call print_string
    mov di, name
    call read_name
    mov si, name
    call print_string

    cli                ; Turn off interrupts        
endloop:
    hlt                ; Halt processor until next interrupt encountered
    jmp endloop        ; Jump back just in case we get an MNI (non-maskable interrupt)

read_name:
read_char:
    mov ah, 0h         ; read character from keyboard
    int 0x16           ; store it in AL
    cmp al, 0x0d       ; check for enter
    je stop_reading
    mov [di], al       ; save it in the buffer
    inc di             ; next char
    mov ah, 0eh        ; display character in AL
    int 0x10           ; echo it
    jmp read_char      ; an so on
stop_reading:
    mov byte [di], 0   ; NUL terminate buffer
    mov si, EoL
    call print_string
    ret

print_char:
    mov ah, 0x0e       ; one char
    mov bh, 0x00       ; page number
    mov bl, 0x07       ; font color
    int 0x10
    ret

print_string:
next_char:
    mov al, [si]
    inc si
    or al, al
    jz exit_function
    call print_char
    jmp next_char
exit_function:
    ret

;data
HelloString db 'Enter your name', 0xd, 0xa, 0
name times 20 db 0
EoL db 0xd, 0xa, 0

times 510 - ($ - $$) db 0;
dw 0xaa55

---

我强烈建议使用BOCHS 来调试引导加载程序。它有一个内置调试器，可以理解实模式和实模式寻址，并且比 QEMU

更适合调试引导加载程序