调用 x64 汇编函数后 C++ 变量重置为 0

Question

我正在尝试从具有四个参数的 C++ 代码调用 x64 汇编函数，并且汇编函数每次都将第一个参数重置为零。请在下面找到代码 sn-p。

C++ 代码：test.cpp

#include <iostream>

extern "C" int IntegerShift_(unsigned int a, unsigned int* a_shl, unsigned int* a_shr, unsigned int count);

int main(int argc, char const *argv[])
{
    unsigned int a = 3119, count = 6, a_shl, a_shr;
    std::cout << "a value before calling " << a << std::endl;
    IntegerShift_(a, &a_shl, &a_shr, count);
    std::cout << "a value after calling " << a << std::endl;
    return 0;
}

x64 汇编代码：test.asm

section .data
section .bss
section .text

global IntegerShift_
    IntegerShift_:
        ;prologue
        push rbp
        mov rbp, rsp

        mov rax, rdi
        shl rax, cl
        mov [rsi], rax
        mov rax, rdi
        shr rax, cl
        mov [rdx], rax
        xor rax,rax

        ;epilogue
        mov rbp, rsp
        pop rbp
        ret

我正在以下环境中工作。

操作系统 - Ubuntu 18.04 64 位
汇编程序 - nasm (2.13.02)
C++ 编译器 - g++ ( 7.4.0)
处理器 - Intel® Pentium(R) CPU G3240 @ 3.10GHz × 2

我正在编译我的代码，如下所示

$ nasm -f elf64 -g -F dwarf test.asm
$ g++ -g -o test test.cpp test.o
$ ./test
$ a value before calling 3119
$ a value after calling 0

但是如果我从汇编函数中注释掉mov [rdx], rax 行，它不会重置variable a 的值。我是 x64 汇编编程的新手，我找不到 rdx 寄存器和变量 a 之间的关系。

Answer 1

unsigned int* a_shl, unsigned int* a_shr 是指向unsigned int 的指针，这是一种 32 位（双字）类型。

你做了两个 qword 存储，mov [rsi], rax 和 mov [rdx], rax，它们存储在指向对象之外。

C 等效项是一个接受unsigned int* 参数并执行
*(unsigned long)a_shr = a>>count; 的函数。这当然是 UB，像这样的行为（覆盖其他变量）几乎是你所期望的。

---

大概你编译时禁用了优化，所以调用者实际上从堆栈中重新加载了a。它在堆栈框架中将a_shr 或a_shl 放在a 旁边，您的一家商店将您的调用者的a 副本归零。

（像往常一样，gcc 在将a 作为第一个参数放入 EDI 时碰巧将 RDI 的高 32 位归零。写入 32 位寄存器零扩展至完整寄存器。所以你的另一个错误；对将 a_shr 的高位垃圾转移到低 32 位，这个调用者并没有咬你。）

更简单的实现：

global IntegerShift    ; why the trailing underscore?  That's weird for no reason.
    IntegerShift:
        ;prologue not needed, we don't even use the stack
        ; so don't waste instructions making a frame pointer.

        mov   eax, edi
        shl   rax, cl              ; a<<count
        mov   [rsi], eax           ; 32-bit store

        ;mov rax, rdi       ; we can just destroy our local a, we're done with it
        shr    edi, cl             ; a>>count
        mov   [rdx], edi           ; 32-bit store

        xor   eax, eax             ; return 0
        ret

xor eax, eax 是清零 64 位寄存器的最有效方法（不会浪费 REX 前缀）。而且您的返回值无论如何只有 32 位，因为您声明了它int，所以使用 64 位寄存器没有任何意义。

顺便说一句，如果您有可用的 BMI2（不幸的是，您的预算 Pentium CPU 上没有），您可以避免所有寄存器复制，并且在 Intel CPU 上更高效（SHL/RX 仅为 1 uop 而不是3 for shl/r reg, cl 因为 cl=0 情况下的旧版 x86 FLAGS 未修改语义）

    shlx   eax, edi, ecx
    shrx   edi, edi, ecx
    mov   [rsi], eax
    mov   [rdx], edi
    xor   eax, eax
    ret