使用条件跳转添加奇数的汇编程序

Question

我有一个任务：

使用条件跳转编写汇编代码以添加以下 15 个奇数。

奇数：3、5、7、9、11、13、15、17、19、21、23、25、27、29、31

我提出了这个解决方案。我想检查一下它有什么问题...

[org 0x0100]
mov bx, num1
mov cx, 15
mov ax, 0
li:
add ax, [bx]
add bx, 2
sub cx, 1
jnz li
mov ax, 0x4c00
int 0x21
num1: dw 3, 5, 7, 9, 11, 13, 15, 17, 19, 21,23,25,27,29,31

Answer 1

这当然是一个的方法，你唯一需要注意的是你在ax中累积了总和，但是当你退出时你覆盖了ax带有int 21, fn 4c的程序。

巧合的是，这些数字总和为 255，因此它实际上 适合 到 al，这是该中断用于返回代码的寄存器（请参阅 Ralf Brown's excellent interrupt list）。

DOS 是否会用它做任何智能的事情，我不能说:-)

为了在退出程序时保留al，只需这样做：

mov  ah, 0x4c
int  0x21

---

您可能要考虑做的另一件事是直接打印该项目而不是退回它。以下代码显示了如何使用我的工具库中的一个函数来执行此操作，该函数能够将al 寄存器输出为以十为底的值：

        org     00100h

        mov     bx, num1
        mov     cx, 15
        mov     ax, 0
li:
        add     ax, [bx]
        add     bx, 2
        sub     cx, 1
        jnz     li

        call    prt_byte

        mov     ah, 04ch
        int     021h

num1:   dw      3, 5, 7, 9, 11, 13, 15, 17, 19, 21,23,25,27,29,31
eoln:   db      0dh, 0ah, '$'

prt_byte:
        push    ax
        push    bx
        push    dx

        cmp     ax, 100
        jl      skip_h

        push    ax

        mov     bl, 100             ; divide ax by 100.
        div     bl
        mov     ah, 0

        call    prt_digit

        mul     bl                  ; remove hundreds digit.
        mov     bx, ax
        pop     ax
        sub     ax, bx

skip_h:
        cmp     ax, 10
        jl      skip_t

        push    ax

        mov     bl, 10              ; divide ax by 10.
        div     bl
        mov     ah, 0

        call    prt_digit

        mul     bl                  ; remove tens digit.
        mov     bx, ax
        pop     ax
        sub     ax, bx

skip_t:
        call    prt_digit

        mov     dx, offset eoln
        mov     ah, 9
        int     021h

        pop     dx
        pop     bx
        pop     ax
        ret

prt_digit:
        push    ax                  ; save registers.
        push    dx

        mov     dx, ax              ; put in correct register.
        add     dx, '0'             ; turn into digit.
        mov     ah, 2               ; print.
        int     021h

        pop     dx                  ; restore registers and return.
        pop     ax
        ret