有没有办法在 NASM 中将整数转换为十六进制？ [复制]

Question

如果有办法获得一个十进制值（0-9），有人可以向我解释一下吗？我正在做的一个项目需要它。我想做MOV SI, [CX:DX]，但后来我有一种行不通的感觉。所以我决定在网上搜索，但我想要的主题不会出现。那么有人可以告诉我是否有办法从 0 到 9 获得 1 个十进制值？

我尝试过： MOV BL, 1000 MOV AH, 00h DIV DX

是不是我做错了什么？

将编译器 NASM 与 16 位代码一起使用。

Answer 1

从 cmets 看来，您想要的是这样的：

;Input
; cx    Clock ticks since midnight
;
;Output
; ax    Most significant non-zero decimal digit of clocks since midnight (unless
;       clocks since midnight is zero, where zero will be returned)
;
;Trashed
; none (contents of all registers not used for outputs are preserved)

get_most_significant_decimal_digit:
    mov ax,cx           ;ax = numerator = clocks since midnight
    cmp ax,10           ;Is it already small enough?
    jb .done            ; yes

    push bx
    push dx

    mov bx,10           ;bx = divisor (constant value 10)
.continue:
    xor dx.dx           ;dx:ax = numerator zero extended to 32 bits
    div bx              ;ax = numerator / 10

    cmp ax,10           ;Is it small enough now?
    jae .continue       ; no, keep going

    pop dx
    pop bx
.done:
    ret

注意：为了获得最佳性能，最好为每个分区使用不同的除数，并选择除数以尽量减少除数。例如。 “如果不小于 10000，则除以 10000”然后“如果不小于 100，则除以 100”然后“如果不小于 10，则除以 10”。很难说性能改进是否值得额外的复杂性（以及更差的代码可读性）。

三思而后行；它并没有那么混乱（未经测试，NASM 语法）：

    section .data
const10000:  dw 10000
const100:    dw 100
const10:     dw 10
    section .text

;Input
; cx    Clock ticks since midnight
;
;Output
; ax    Most significant non-zero decimal digit of clocks since midnight (unless
;       clocks since midnight is zero, where zero will be returned)
;
;Trashed
; none (contents of all registers not used for outputs are preserved)

get_most_significant_decimal_digit:
    mov ax,cx           ;ax = numerator = clocks since midnight
    push dx

    cmp ax,10000
    jb .l1
    xor dx,dx
    div word [const10000]
.l1:
    cmp ax,100
    jb .l2
    xor dx,dx
    div word [const100]
.l2:
    cmp ax,10
    jb .l3
    xor dx,dx
    div word [const10]
.l3:
    pop dx
    ret

对于这种替代方案，“更糟糕的情况”是 3 个部门和 3 个分支（而不是之前的方法的 4 个部门和 5 个分支）。