尽管有尾调用位置但堆栈溢出但仅在 64 位

Question

源自this question，我有这个小F#代码（github）根据正态分布生成随机值：

// val nextSingle : (unit -> float32)
let nextSingle =
    let r = System.Random()
    r.NextDouble >> float32

// val gauss : (float32 -> float32 -> seq<float32>)
let gauss mean stdDev =
    let rec gauss ready = seq {
        match ready with
        | Some spare ->
            yield spare * stdDev + mean
            yield! gauss None
        | _ ->
            let rec loop () =
                let u = nextSingle() * 2.f - 1.f
                let v = nextSingle() * 2.f - 1.f
                let s = pown u 2 + pown v 2
                if s >= 1.f || s = 0.f then loop() else
                u, v, s
            let u, v, s = loop()
            let mul = (*)(sqrt(-2.f * log s / s))
            yield mul u * stdDev + mean
            yield! mul v |> Some |> gauss
    }
    gauss None

在我看来，这似乎只应在尾调用位置调用自身，因此在启用 TCO 时永远不会导致StackOverflowException。但在运行 64 位 时它确实。 不在运行 32 位（即项目设置中的“首选 32 位”复选框）时。

我正在使用 .NET Framework 4.5.2 和 F# 4.4.0.0。

谁能解释造成问题的原因？

Answer 1

看起来像是编译器的序列表达式编译机制中的一个错误。这是一个简化的重现：

let rec loop r = seq {
    if r > 0 then
        let rec unused() = unused()
        yield r
        yield! loop r
}

printfn "%i" (Seq.nth 10000000 (loop 1))

显然，未使用的递归定义的存在不应该影响这是否会产生堆栈溢出，但确实会。