在函数调用窗口批处理脚本中转义 PIPE 字符

Question

我正在编写一个函数来执行 shell 命令并在批处理脚本中捕获其输出。

:runShellCmd
   setlocal EnableDelayedExpansion
   SET lf=-
   FOR /F "delims=" %%i IN ('%~1') DO if "%out%" == "" (set out=%%i) else (set out=!out!%lf%%%i)
   echo "Cmd output: %out%"
   SET "funOut=%out%"
ENDLOCAL & IF "%~1" NEQ "" SET %~2=%out%
goto :EOF

我已经成功地传递了简单的命令并获得了输出。但是对于像

这样的电话

CALL :runShellCmd "echo Jatin Kumar | find /c /i "jatin"" 失败并出现错误unexpected | character。

我知道我们需要在 for 中使用 ^ 转义 |，但如果我尝试在函数参数字符串中传递 ^|，它会将其更改为 ^^|，这又会引发错误。

我错过了什么吗？

Answer 1

这是CALL 命令的效果。

CALL 命令在一个批处理解析器阶段中将所有插入符号加倍。
通常你不会看到这一点，因为插入符号将在加倍后直接用作转义字符。

看到这个

call echo ^^^^
call call echo ^^^^
call call call echo ^^^^

call echo "^^^^"
call call echo "^^^^"
call call call echo "^^^^"

输出

^^
^^
^^
"^^^^^^^^"
"^^^^^^^^^^^^^^^^"
"^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^"

但是你怎么能逃脱你的管道字符呢？
你不能！

但您可以在函数中添加脱字符号。

:runShellCmd
   setlocal EnableDelayedExpansion
   set "param=%~1"
   set param
   set "param=!param:^^=^!"
   for .... ('!param!')

或者你可以在调用你的函数时使用转义技巧。

set "caret=^"
CALL :runShellCmd "echo Jatin Kumar %%caret%%| find /c /i "

这可行，因为%%caret%% 将在CALL caret doubling phase 之后展开。

Answer 2

@echo off
    setlocal enableextensions disabledelayedexpansion 

    call :test "echo(this|find "t""
    exit /b

:test
    set "x=%~1"
    for /f "delims=" %%f in ('%x:|=^|%') do echo [%%f]

我想我错过了一些东西，因为这对我有用。

已编辑 - 这应该是更通用的解决方案。不是防弹的，而是骷髅。

@echo off
    setlocal enableextensions disabledelayedexpansion 

    call :test "(echo(this&echo(that)|find "t" 2>nul|sort&echo end"
    exit /b

:test
    set "x=%~1"
    set "x=%x:|=^|%"
    set "x=%x:>=^>%"
    set "x=%x:<=^<%"
    set "x=%x:&=^&%"
    set "x=%x:)=^)%"
    for /f "delims=" %%f in ('%x%') do echo [%%f]