将系统命令的输出分配给变量

Question

我想在 awk 脚本中运行 system 命令并将其输出存储在一个变量中。我一直在尝试这样做，但是命令的输出总是进入 shell，我无法捕获它。关于如何做到这一点的任何想法？

例子：

$ date | awk --field-separator=! {$1 = system("strip $1"); /*more processing*/}

应调用strip 系统命令，而不是将输出发送到shell，应将输出分配回$1 以进行更多处理。现在，它正在向 shell 发送输出并将命令的 retcode 分配给 $1。

Answer 1

注意：协进程是 GNU awk 特定的。 无论如何，另一种选择是使用 getline

cmd = "strip "$1
while ( ( cmd | getline result ) > 0 ) {
  print  result
} 
close(cmd)

调用close(cmd) 将防止awk 在多次调用后抛出此错误：

致命：无法打开管道`...'（打开的文件太多）

Answer 2

要在awk 中运行系统命令，您可以使用system() 或cmd | getline。

我更喜欢cmd | getline，因为它允许您将值捕获到变量中：

$ awk 'BEGIN {"date" |  getline mydate; close("date"); print "returns", mydate}'
returns Thu Jul 28 10:16:55 CEST 2016

更一般地，您可以将命令设置为变量：

awk 'BEGIN {
       cmd = "date -j -f %s"
       cmd | getline mydate
       close(cmd)
     }'

请注意，如果您有多个结果，请务必使用 close() 以防止出现“打开的文件过多”错误（感谢 mateuscb 在 cmets 中指出这一点）。

---

使用system()，会自动打印命令输出，你可以捕捉到的值就是它的返回码：

$ awk 'BEGIN {d=system("date"); print "returns", d}'
Thu Jul 28 10:16:12 CEST 2016
returns 0
$ awk 'BEGIN {d=system("ls -l asdfasdfasd"); print "returns", d}'
ls: cannot access asdfasdfasd: No such file or directory
returns 2

Answer 3

想通了。

我们使用awk的Two-way I/O

{
  "strip $1" |& getline $1
}

将$1传递给strip，getline将输出从strip返回到$1

Answer 4

gawk '{dt=substr($4,2,11); gsub(/\//," ",dt); "date -d \""dt"\" +%s"|getline ts; print ts}'

Answer 5

当你需要处理一个 grep 输出时可以使用它：

echo "some/path/exex.c:some text" | awk -F: '{ "basename "$1"" |& getline $1; print $1 " ==> " $2}'

option -F: 告诉 awk 使用 : 作为字段分隔符

"basename "$1"" 在第一个字段上执行 shell 命令 basename

|& getline $1 读取子流中前一个 shell 命令的输出

output:
exex.c ==> some text

Answer 6

我正在使用 macOS 的 awk，我还需要命令的退出状态。所以我也扩展了@ghostdog74 的解决方案来获取退出状态：

如果非零退出状态则退出：

cmd = <your command goes here>
cmd = cmd" ; printf \"\n$?\""

last_res = ""
value = ""        

while ( ( cmd | getline res ) > 0 ) {

    if (value == "") {
        value = last_res
    } else {
        value = value"\n"last_res
    }

    last_res = res
}

close(cmd)

# Now `res` has the exit status of the command
# and `value` has the complete output of command

if (res != 0) {
    exit 1
} else {
    print value
}

所以基本上我只是将cmd 更改为在新行上打印命令的退出状态。执行上述while 循环后，res 将包含命令的退出状态和 value 将包含命令的完整输出。

老实说，这不是一个很好的方法，我自己也想知道是否有更好的方法。