确定寄存器的值是否等于零的最简单方法是什么？

Question

我将 x86 程序集与 Irvine 库一起使用。

检查寄存器值是否为零的最简单方法是什么？

我使用 cmp 指令，但我正在寻找替代方法。 这是我使用 cmp 指令的代码，寄存器是 ebx

    cmp ebx,0
    je equ1
    mov ebx,0
    jmp cont
equ1:
    mov ebx,1
    jmp cont
cont:
    exit

这“布尔化”一个值，产生一个 0 或 1，就像 C 中的 int ebx = !!ebx 一样。

Answer 1

对于如何确定的“最简单”或“不关心细节”的答案可能是：

    ; here ebx is some value, flags are set to anything
    test   ebx,ebx   ; CF=0, ZF=0/1 according to ebx
    jz     whereToJumpWhenZero
    ; "non-zero ebx" will go here

    ; Or you can use the inverted "jnz" jump to take
    ; a branch when value was not zero instead of "jz".

有一个详细的answer from Peter Cordes to "testl eax against eax?" question 推理关于设置标志等。还有一个链接到另一个类似的答案，但从性能的角度推理为什么它是最好的方法。 :)

如何在ebx 为零时将其他一些寄存器（我将选择eax）设置为1，当ebx 为非零时设置为0（ebx 本身的非破坏性方式）：

    xor   eax,eax  ; eax = 0 (upper 24 bits needed to complete "al" later)
    test  ebx,ebx  ; test ebx, if it is zero (ZF=0/1)
    setz  al       ; al = 1/0 when ZF=1/0 (eax = 1/0 too)

或者当ebx 为零/非零时如何将ebx 本身转换为1/0：

    neg   ebx      ; ZF=1/0 for zero/non-zero, CF=not(ZF)
    sbb   ebx,ebx  ; ebx = 0/-1 for CF=0/1
    inc   ebx      ; 1 when ebx was 0 at start, 0 otherwise

或者当ebx 为零/非零时如何将ebx 本身转换为1/0，其他变体（在“P6”到​​“Haswell”核心上更快）：

    test  ebx,ebx  ; ZF=1/0 for zero/non-zero ebx
    setz  bl       ; bl = 1/0 by ZF (SETcc can target only 8b r/m)
    movzx ebx,bl   ; ebx = bl extended to 32 bits by zeroes

等，等等...这取决于您的测试之前发生的情况，以及您真正想要的测试输出，有许多可能的方法（针对不同情况是最佳的，对于不同的情况是最佳的）不同的目标 CPU）。

---

我将添加一些更常见的情况...从 N 到零的计数器循环向下计数，循环 N 次：

    mov   ebx,5   ; loop 5 times
exampleLoop:
    ; ... doing something, preserving ebx
    dec   ebx
    jnz   exampleLoop ; loop 5 times till ebx is zero

如何处理word(16b)数组的5个元素（以数组[0]、数组[1]、...顺序访问它们）：

    mov   ebx,-5
    lea   esi,[array+5*2]
exampleLoop:
    mov   ax,[esi+ebx*2]  ; load value from array[i]
    ; process it ... and preserve esi and ebx
    inc   ebx
    jnz   exampleLoop  ; loop 5 times till ebx is zero

---

再举一个例子，不知怎的，我很喜欢这个：

当ebx 为零/非零并且您在某个寄存器中已经有值1（ecx 在示例）：

    ; ecx = 1, ebx = some value
    cmp   ebx,ecx  ; cmp ebx,1 => CF=1/0 for ebx zero/non-zero
    sbb   eax,eax  ; eax = -1 (~0) / 0 for CF=1/0 ; ebx/ecx intact

-1 可能看起来和 1 一样实用（至少用于索引目的），但 -1 也可以作为完整位掩码用于进一步的 and/xor/or 操作，因此有时它更方便。

Answer 2

使用旗帜，卢克
您可以通过检查零标志来测试寄存器是否为零。
如果寄存器通过影响标志（或更具体地说，零标志）的某些操作获得其值，那么您不必做任何事情，因为零标志已经反映了存储在该寄存器中的值。

仅在需要时进行测试
如果您不能保证已设置标志，则必须使用测试操作。
这些操作有两种形式：破坏性和非破坏性。

您可以在以下位置查看指令列表及其更改的标志：http://ref.x86asm.net——更具体地说，是：http://ref.x86asm.net/coder32-abc.html

mov 和 lea 指令从不改变标志，因此需要帮助。大多数其他指令设置至少一个标志。

不要创建错误的依赖项
如果您需要测试寄存器是否为零，但又不想更改其值，请使用test 指令。
您不应该使用or 或and 指令来检查寄存器，因为CPU 可能不知道or/and 可以非破坏性地使用并且可能无法应用某些优化。 对此的技术术语是“错误依赖”。该寄存器需要 ebx 并且“认为”它最近已更改，因此它等待结果最终确定。

test ebx, ebx  ; <-- CPU knows ebx was not altered, no stalls on subsequent reads.
or   ebx, ebx  ; <-- CPU 'thinks' ebx was changed, stall on subsequent read.

如果您希望零状态反映在另一个寄存器中，您可以简单地将mov ebx 映射到另一个寄存器。

将值减少为布尔值
如果要将寄存器减少为布尔值（如果非零则为 True，否则为 False），请使用以下序列之一：

; ebx holds the value to reduce to a boolean.
; eax is an unused register.

xor eax, eax   ; eax = 0
sub eax, ebx   ; eax = 0 - ebx; CF (carry flag) = 1 if ebx <> 0
sbb ebx, ebx   ; ebx = ebx - ebx - CF
               ; <<-- ebx = -1 if non zero, 0 if zero

xor eax, eax   ; eax = 0
sub eax, ebx   ; eax = - ebx; CF = 1 if ebx <> 0
adc ebx, eax   ; ebx = (ebx + -ebx) aka 0 + CF
               ; <<== ebx = 1 if non zero, 0 if zero

test ebx, ebx  ; force ZF to be correct
setnz al       ; Store 1 if non-zero, 0 otherwise in byte register AL.

请注意，由于与“部分寄存器写入”相关的停顿，使用字节寄存器可能会出现问题。

Answer 3

你可以使用：

or ebx, 0 ;This does nothing, just triggers the zero flag if ebx is zero
jnz notZero 
or ebx, 1 ;ebx was zero, then ebx is 1
notZero: