使用 WebClient 处理 VB.NET SSIS 脚本中的异常（FTP 下载）

Question

在 SSIS 中，我使用 VB.NET 脚本任务 从 FTP 文件夹下载文件。

脚本如下

Imports System
Imports System.Data
Imports Microsoft.SqlServer.Dts.Runtime
Imports System.Net

Public Class ScriptMain
    Public Sub Main()
        Dim objWebClient As WebClient = New WebClient()
        Dim strDownloadURL As String = "ftp://mydownloadhosting.com/myfolder/" + Dts.Variables("GetDate").Value.ToString() + "_daily.xml"
        Dim strFileName As String = Dts.Variables("WorkingFile").Value.ToString()
        Dim wp As WebProxy = New WebProxy("my.proxy.local", 1234)

        objWebClient.Proxy = wp
        objWebClient.Credentials = New System.Net.NetworkCredential("username", "password")
        objWebClient.DownloadFile(strDownloadURL, strFileName)

        Dts.TaskResult = Dts.Results.Success
    End Sub
End Class

它工作正常，但我的目标是管理异常，特别是区分：

• 找不到文件
• 所有其他问题（超时、代理问题...）

我对如何使用WebClient() 管理异常进行了一些研究，我发现了这些：

• How to catch 404 WebException for WebClient.DownloadFileAsync
• How do I check a WebClient Request for a 404 error
• Handling two WebException's properly

它们给出以下不同形式：

try
{
    // try to download file here
}
catch (WebException ex)
{
    if (ex.Status == WebExceptionStatus.ProtocolError)
    {
        if (((HttpWebResponse)ex.Response).StatusCode == HttpStatusCode.NotFound)
        {
            // handle the 404 here
        }
    }
    else if (ex.Status == WebExceptionStatus.NameResolutionFailure)
    {
        // handle name resolution failure
    }
}

主要问题是我的代码是在 VB.NET 中，并且所有发布的答案都是用 C# 编写的，如何使 try/catch 构造来处理我的代码中的异常？

Answer 1

VB.NET 中的等效代码是：

Try
    ' try to download file here
Catch ex As WebException
    If ex.Status = WebExceptionStatus.ProtocolError Then
        If DirectCast(ex.Response, HttpWebResponse).StatusCode = HttpStatusCode.NotFound Then
            ' // handle the 404 here
        End If
    ElseIf ex.Status = WebExceptionStatus.NameResolutionFailure Then
        ' handle name resolution failure
    End If
End Try

---

虽然上面/您的代码是用于 HTTP，而不是用于 FTP。 FTP 有不同的状态码。

对于 FTP，请使用：

• FtpWebResponse 和
• FtpStatusCode。

有关一些 FTP 示例，请参阅：

• C#：How to check if file exists on FTP before FtpWebRequest
• VB.NET：VB.net - see if remote file exists

Answer 2

有很多C#转VB.NET的转换器，需要转换简单代码的时候可以参考：

• Telerik C#/VB.NET online code converter
• Instant VB – Our C# to VB.NET Converter

等效的VB.NET代码为：

Imports System
Imports System.Data
Imports Microsoft.SqlServer.Dts.Runtime
Imports System.Net

Public Class ScriptMain
    Public Sub Main()

        Try

            Dim objWebClient As WebClient = New WebClient()
            Dim strDownloadURL As String = "ftp://mydownloadhosting.com/myfolder/" + Dts.Variables("GetDate").Value.ToString() + "_daily.xml"
            Dim strFileName As String = Dts.Variables("WorkingFile").Value.ToString()
            Dim wp As WebProxy = New WebProxy("my.proxy.local", 1234)

            objWebClient.Proxy = wp
            objWebClient.Credentials = New System.Net.NetworkCredential("username", "password")
            objWebClient.DownloadFile(strDownloadURL, strFileName)

            Dts.TaskResult = Dts.Results.Success

        Catch ex As WebException

            If ex.Status = WebExceptionStatus.ProtocolError Then

                If (CType(ex.Response, HttpWebResponse)).StatusCode = HttpStatusCode.NotFound Then

                   'handle the 404 here

                End If
            ElseIf ex.Status = WebExceptionStatus.NameResolutionFailure Then

                'handle name resolution failure

            End If

            Dts.TaskResult = Dts.Results.Failure

        End Try


    End Sub
End Class